比较 where 子句中的日期值

Question

我正在尝试从表中获取当前月份的记录。 由于这将是一项自动化的每月工作，因此我无法在 where 子句中给出明确的值。 所以我使用 intnx function 来获取月份的开始和结束日期。 然后将它们与 where 子句中的表值（日期）进行比较。 我尝试了不同的日期格式，但每次我收到相同的错误：“错误：使用等于 (=) 的表达式具有不同数据类型的组件。”

下面是我的脚本。 我究竟做错了什么？

DATA _NULL_;
CALL 
SYMPUT('MonthStart',TRIM(PUT(INTNX('MONTH',TODAY(),0,'B'),ddmmyys10.)));
CALL 
SYMPUT('MonthEnd',TRIM(PUT(INTNX('MONTH',TODAY(),0,'E'),ddmmyys10.)));
RUN;

%PUT &MonthStart.;
%PUT &MonthEnd.;


PROC SQL;
CREATE TABLE CURRENT_MONTH_ACTIVITY AS
SELECT * FROM MONTH_END_BASE
WHERE ACTIVITY_DATE >= '&MonthStart.' AND ACTIVITY_DATE <= '&MonthEnd.' ;
QUIT;

提前致谢！

Answer 1

您可以使用INTCK function 检查从当前日期到活动日期的月份范围何时为零。

where INTCK('MONTH', today(), activity_date) = 0;

另一种方法是使用宏直接between点之间“生成代码”。 您不需要数据步骤来填充稍后使用的宏变量。

例子：

data have;
  do activity_date = today() - 365 to today() + 365;
    output;
  end;
  format activity_date yymmdd10.;
run;

data want;
  set have;
  where intck('MONTH', today(), activity_date) = 0;
run;

data want;
  set have;
  where activity_date 
    between 
      %sysfunc(INTNX(MONTH, %sysfunc(today()), 0, B)) 
    and
      %sysfunc(INTNX(MONTH, %sysfunc(today()), 0, E)) 
  ;
run;

Answer 2

我同意汤姆的观点。 可能变量 activate_date 是具有日期格式的数字类型，然后将解决方案分配给 MonthStart 和 MonthEnd 一个数值。

DATA _NULL_;
    CALL SYMPUT('MonthStart',INTNX('MONTH',TODAY(),0,'B'));
    CALL SYMPUT('MonthEnd',INTNX('MONTH',TODAY(),0,'E'));
RUN;

%PUT &MonthStart.;
%PUT &MonthEnd.;



PROC SQL;
CREATE TABLE CURRENT_MONTH_ACTIVITY AS
SELECT * FROM MONTH_END_BASE
WHERE ACTIVITY_DATE >= &MonthStart. AND ACTIVITY_DATE <= &MonthEnd. ;
QUIT;