如何在记录结构中声明联合？

Question

我正在尝试定义TWaveFormatExtensible类型，但我不确定我是否正确声明了Samples联合。 这是 header 文件（Windows SDK 10.0.17763.0）的原始声明：

typedef struct {
    WAVEFORMATEX    Format;
    union {
        WORD wValidBitsPerSample;       /* bits of precision  */
        WORD wSamplesPerBlock;          /* valid if wBitsPerSample==0 */
        WORD wReserved;                 /* If neither applies, set to zero. */
    } Samples;
    DWORD           dwChannelMask;      /* which channels are */
                                        /* present in stream  */
    GUID            SubFormat;
}

这就是我尝试过的：

type
  TWAVEFORMATEX = record
    wFormatTag: Word;
    nChannels: LongWord;
    nSamplesPerSec: Word;
    nAvgBytesPerSec: LongWord;
    nBlockAlign: Word;
    wBitsPerSample: Word;
    cbSize: Word;
  end;

  TWaveFormatExtensible = record
    Format: TWAVEFORMATEX;
    dwChannelMask: LongWord;
    SubFormat: Integer;
    case Word of
      0: (wValidBitsPerSample: Word;);
      1: (wSamplesPerBlock: Word;);
      2: (wReserved: Word;);
  end;

但这是不正确的。 如何在 Delphi 的记录结构中声明联合？

Answer 1

结构的字段必须与原始 (C++) 声明中的顺序相同。 但是有一个问题：原始声明将Samples变体放在记录的中间，这在 Delphi 中是不允许的。

您可以通过将变体部分声明为单独的记录，然后将该记录作为字段包含在最终结构中来解决此问题。

TWaveFormatExtensibleSamples = record
case Word of
  0: (wValidBitsPerSample: Word;);
  1: (wSamplesPerBlock: Word;);
  2: (wReserved: Word;);
end;

然后构造最终的结构：

TWaveFormatExtensible = record
  Format: TWAVEFORMATEX;
  Samples: TWaveFormatExtensibleSamples;
  dwChannelMask: DWORD;
  SubFormat: TGUID; 
end;

---

编辑：具有变体部分的记录的文档，state：

一个记录类型可以有一个变体部分，它看起来像一个 case 语句。 变体部分必须跟在记录声明中的其他字段之后。

这涉及没有封闭记录声明的变体部分。

但是，正如 Remy Lebeau 所指出的，具有变体部分的记录可以直接在TWaveFormatExtensible声明中声明为结构的一部分，在其他字段之间：

TWaveFormatExtensible = record
  Format: TWAVEFORMATEX;
  Samples: record
    case Word of
    0: (wValidBitsPerSample: Word;);
    1: (wSamplesPerBlock: Word;);
    2: (wReserved: Word;);
  end;
  dwChannelMask: DWORD;
  SubFormat: TGUID;
end;

所以这可以与单独声明的TWaveFormatExtensibleSamples记录一起使用。