Ada - 如何初始化包含 File_Type 成员的有限标记类型？

Question

在下面的代码中，Mix_Card_Reader 继承自 Mix_IO_Device，后者是一个抽象的标记记录。

以前它包含一个Positive和两个Stream_Access成员。 我想更改代码，以便它使用File_Type成员。

这样做的原因是我希望这种类型的每个实例都能够在需要时打开和关闭其文件，或者如果需要则根本不打开和关闭其文件。

问题是我无法初始化此继承类型，因为File_Type是有限类型。 我怎样才能写我的Create_Mix_Card_Reader function 来允许这个？

.广告...

   type Mix_IO_Device is abstract tagged limited
      record
         Block_Size : Positive;
         Input_File : File_Type;
         Output_File : File_Type;
      end record;

   type Mix_Card_Reader is new Mix_IO_Device with null record;

.adb...

   function Create_Mix_Card_Reader return Mix_IO_Device_Access is
      Ret : Mix_IO_Device_Access := new Mix_Card_Reader'(16, null, null);
   begin
      return Ret;
   end Create_Mix_Card_Reader;

GNAT 抱怨我无法将null, null传递到这对File_Type成员中，因为它们当然不兼容，空值是从以前有Stream_Access成员时遗留下来的。 似乎我必须在这里传递一些东西，但我不想为了安抚编译器而过早地打开文件。

该怎么办？

编辑：我有几个明显的选择：

• 改用access File_Type （但我仍然必须在其他地方维护文件的打开/关闭）。
• 将所有 File_Type 对象分别存储在一个数组中，并像以前一样使用 Streams 来引用它们，但这看起来很混乱。

Answer 1

这应该可以解决问题：

function Create_Mix_Card_Reader return Mix_IO_Device_Access is
   Ret : Mix_IO_Device_Access := new Mix_Card_Reader'(
     16, Input_Type => <>, Ouptut_Type => <>);
begin
   return Ret;
end Create_Mix_Card_Reader;

方框表示法是默认值的占位符。 您至少需要 Ada 2005 才能在聚合中使用它，并且不得使用位置表示法，详细信息在Ada 2005 Rationale中进行了说明。 如果需要，您可以将这两个作业缩短给others => <> 。

Answer 2

您实际上不需要初始化File_Type变量，因为它们开始时已初始化（但未打开）。

我的印象是您没有开始使用访问类型？ 试试这个（不是所提出问题的答案，但可能仍然有用）：

with Ada.Text_IO; use Ada.Text_IO;
package Wossname is

   type Mix_IO_Device is abstract tagged limited
      record
         Block_Size : Positive;
         Input_File : File_Type;
         Output_File : File_Type;
      end record;

   type Mix_Card_Reader is new Mix_IO_Device with null record;

   function Create_Mix_Card_Reader return Mix_IO_Device'Class;

end Wossname;

我不是 100% 确定这里的确切合法性，但我认为这是“就地初始化”：

package body Wossname is

   function Create_Mix_Card_Reader return Mix_IO_Device'Class is
   begin
      return Ret : Mix_Card_Reader do
         Ret.Block_Size := 16;
      end return;
   end Create_Mix_Card_Reader;

end Wossname;

正如你所看到的，它编译（并运行）。好的。

procedure Wossname.Test is
   Reader : Mix_IO_Device'Class := Create_Mix_Card_Reader;
begin
   begin
      Create (Reader.Output_File, Name => "wossname.out", Mode => Out_File);
   exception
      when Use_Error =>
         Open (Reader.Output_File, Name => "wossname.out", Mode => Out_File);
   end;
   Put (Reader.Output_File, "hi!");
   Close (Reader.Output_File);
end Wossname.Test;