比较两个字符串并返回匹配的单词数

Question

总的来说，我对 Clojure 和编程还很陌生。 有没有一种方法可以逐字比较两个字符串，然后返回两个字符串中匹配单词的数量？ 另外如何计算字符串中的数字？

例如：比较 string1 " Hello Alan and Max"和 string2 "Hello Alan and Bob"将返回“3”（例如 Hello Alan 并且两个字符串中的单词都匹配）并且查找 string1 中的单词数将导致数字4.

谢谢

Answer 1

让我们把它分解成一些小问题：

逐字比较两个字符串

首先，我们需要一种方法来获取一个字符串并返回它的单词。 一种方法是假设任何空格都在分隔单词，因此我们可以使用带有clojure.string/split的正则表达式：

(defn string->words [s]
  (clojure.string/split s #"\s+"))

(string->words "Hello world, it's me, Clojure.")
=> ["Hello" "world," "it's" "me," "Clojure."]

返回两个字符串中匹配单词的数量

我能想象到的最简单的方法是建立两个集合，一个代表两个句子中的词集，并找到两个集合的交集：

(set (string->words "a b c a b c d e f"))
=> #{"d" "f" "e" "a" "b" "c"} ;; #{} represents a set

我们可以使用clojure.set/intersection函数来找到两个集合的交集：

(defn common-words [a b]
  (let [a (set (string->words a))
        b (set (string->words b))]
    (clojure.set/intersection a b)))

(common-words "say you" "say me")
=> #{"say"}

要获得（匹配）单词的数量，我们可以使用count函数和上述函数的输出：

(count (common-words "say you" "say me")) ;; => 1

Answer 2

您需要做的是成对比较单词序列的项目，并计算项目的数量，直到第一个不匹配为止。 这是一个几乎逐字逐句的翻译：

(defn mismatch-idx [s1 s2]
  (let [w #"\S+"]
    (->> (map = (re-seq w s1) (re-seq w s2))
         (take-while true?)
         count)))

user> (mismatch-idx "a b c" "qq b c")
;;=> 0
user> (mismatch-idx "a b c" "a x c")
;;=> 1
user> (mismatch-idx "a b c" "a b x")
;;=> 2