VB 将文件从 USB 复制到 FTP，无需整个 root

Question

请有人帮助我完成我们正在进行的项目。 我们使用 HMI 将数据记录到直接连接到 HMI 的 USB 驱动器。 我们的客户需要通过 FTP 访问这些文件。 HMI 有一个可以访问的 FTP 区域，但是没有直接的方法可以在不同位置之间复制这些文件夹。 我可以在后台运行一些 VB 脚本并从 PLC 触发子程序。

对 VB 脚本一无所知，我正在努力让它工作。

此代码仅在包含日期时有效： IO.DirectoryInfo("\\UsbDisk\\Data Logging\\Log Files\\DataSet0\\yyyymmdd") 。

每晚午夜都会创建一个新文件夹，并带有新日期，因此固定日期仅适用于当天。 理想情况下，我希望副本从“UsbDisk\\Data Logging\\Log Files”复制所有内容，忽略“DataSet0\\yyyymmdd”。

提前致谢。

Sub Test
    Dim di As New IO.DirectoryInfo("\UsbDisk\Data Logging\Log Files\DataSet0\20191126")
    Dim Diar1 As IO.FileInfo() = di.GetFiles()
    Dim dra As IO.FileInfo

    For Each dra In Diar1
        System.IO.File.Copy(dra.FullName, "\User\SysmacHMI\FTP\" + dra.Name,True)

    Next
End Sub

Answer 1

您编写了“VB 脚本”，但显示了将在 VB.NET 程序中的代码，因此我将采用后者。 （ vbscript 和 vb.net 有什么区别？ ）

可以遍历所有子目录并从中获取文件，对 VB.NET中的递归文件搜索中显示的代码稍作修改（实际上并未使用递归方法）就足够了。

例如，这是一个完整的 VB.NET 控制台应用程序，使用它：

Option Infer On
Option Strict On

Imports System.IO

Module Module1

    ''' <summary>
    ''' Get the full filenames of the files in the given directory and its subdirectories.
    ''' Errors are ignored.
    ''' </summary>
    ''' <param name="path">Initial directory.</param>
    ''' <returns>A List(Of String) of the full filenames.</returns>
    Public Function GetAllFiles(ByVal path As String) As List(Of String)
        ' Adapted from https://stackoverflow.com/questions/44103640/recursive-file-search-in-vb-net

        Dim files As New List(Of String)
        Dim dirs As New Stack(Of String)
        dirs.Push(path)

        Do While (dirs.Count > 0)
            Dim currentDir = dirs.Pop()
            Try
                files.AddRange(Directory.EnumerateFiles(currentDir))

                For Each d In Directory.EnumerateDirectories(currentDir)
                    dirs.Push(d)
                Next

            Catch ex As Exception
                ' Could have been a permissions problem. Ignore it.
            End Try

        Loop

        Return files

    End Function

    Sub Test()
        'TODO: Make sure these are the correct absolute paths:
        Dim rootDir = "\UsbDisk\Data Logging\Log Files"
        Dim destDir = "\User\SysmacHMI\FTP"

        Dim allTheFiles = GetAllFiles(rootDir)

        For Each f In allTheFiles
            Dim newName = Path.Combine(destDir, Path.GetFileName(f))
            Console.WriteLine("Copy " & f & " to " & newName)
            ' Uncomment the File.Copy line to make it actually do the copy.
            ' File.Copy(f, newName, True)
        Next

    End Sub

    Sub Main()
        Test()

        Console.ReadLine()

    End Sub

End Module

如果它抱怨EnumerateFiles和EnumerateDirectories则使用GetFiles和GetDirectories 。