VBA：返回两个数字之间的连续数字范围[保留]

Question

我有一个IP地址列表（大约65,000个）。
我想找到两个不同数据列之间的IP范围。

因此，例如：
第1栏： abc124
第2栏： abc126

abc124
=> abc125
abc126

这是数据类型的示例：

_第1列__第2列
ab12.200 __ ab12.250
ab12.164 __ ab13.120
ab14.150 __ ab14.220

我尝试解决此问题的一种方法是分隔IP地址的最后一个八位位组，然后尝试执行某种“直到直到”循环。 想法是每次加1，然后将其返回到另一列的末尾，然后在到达范围的另一端后停止。

我试过了，但是我对VBA的知识非常基础。
请问有人有什么建议吗？

Answer 1

我曾经写过这个生成函数。 它返回给定范围内的IP地址数组。

Option Explicit

Sub test()
    Debug.Print Join(GenerateIp4FromRange("192.168.12.164", "192.168.13.120"), ", ")
End Sub

Public Function GenerateIp4FromRange(LowestIP As String, HighestIP As String) As Variant
    Dim LowestIPsplit() As String
    LowestIPsplit = Split(LowestIP, ".")

    Dim HighestIPsplit() As String
    HighestIPsplit = Split(HighestIP, ".")

    Dim GeneratedIPs() As String
    ReDim GeneratedIPs(0)
    GeneratedIPs(0) = LowestIP

    Dim a As Long, b As Long, c As Long, d As Long, i As Long
    a = LowestIPsplit(0)
    b = LowestIPsplit(1)
    c = LowestIPsplit(2)
    d = LowestIPsplit(3)

    Do
        Dim NextIP As String
        ReDim Preserve GeneratedIPs(UBound(GeneratedIPs) + 1)

        d = d + 1
        If d > 255 Then
            d = 1
            c = c + 1
            If c > 255 Then
                c = 1
                b = b + 1
                If b > 255 Then
                    a = a + 1
                End If
            End If
        End If

        NextIP = a & "." & b & "." & c & "." & d
        GeneratedIPs(UBound(GeneratedIPs)) = NextIP

        DoEvents
    Loop Until NextIP = HighestIP Or a > 255

    GenerateIp4FromRange = GeneratedIPs
End Function