有没有办法可以重用 EDN 中定义的键的值？

Question

有没有办法可以重用 EDN 中定义的键值？

例如：如果我有以下 EDN

{
   :abc "value1"
   :def :abc
}

当我在 Clojure 中阅读上面的 EDN 时，我想要传递 'def' 键，value1 是 :abc 的值。 但是目前：当我使用 EDN 读取字符串函数读取它时，会传递 :abc 字符串

Answer 1

普通的 EDN 中没有这样的东西。 但是您可以构建一个两阶段传递，或者通过首先替换 EDN 字符串本身的内容，或者可能更好地在通过操作数据结构解析 EDN 之后执行此操作，例如：

(require '[clojure.edn :as edn])
(require '[clojure.walk :as walk])

(defrecord self [key])
(defn tag-self
  [v]
  (->self v))

(defn custom-readers []
  {'x/self tag-self})

(defn replace-self
  [coll]
  (walk/prewalk
   (fn [form]
     (if (map? form)
       (reduce-kv
        (fn [acc k v]
          (assoc acc k (if (= self (type v))
                         (get form (:key v))
                         v)))
        {}
        form)
       form))
   coll))

(replace-self
 (edn/read-string
  {:readers (custom-readers)}
  "[{:abc \"value1\"
     :def #x/self :abc}
    {:abc {:bbb \"value2\"
           :def #x/self :bbb}
     :def #x/self :abc
     :xyz {:aaa \"value3\"
           :nope #x/self :abc
           :def #x/self :aaa}}]"))

将返回：

[{:abc "value1", :def "value1"}
 {:abc {:bbb "value2", :def "value2"},
  :def {:bbb "value2", :def "value2"},
  :xyz {:aaa "value3", :nope nil, :def "value3"}}]

诀窍是我使用我创建的#x/self标签读取器标记对当前映射的另一个键的引用，它将值包装在一个self记录中。 现在我们只是遍历返回的数据结构，每次遇到self类型时，我们将其替换为同一映射中其:key属性的值。

上述replace-self沃克是递归的，所以你可以看到，它可以处理嵌套的地图，它甚至可以取代self的内部地图本身是引用self引用。 它只进行局部作用域，所以:nope #x/self :abc没有被父映射中的:abc的值替换，并且由于它自己的映射中没有:abc键，它的值被设置为nil 。

自定义标签是可选的，我这样做是因为现在它适用于任何类型的键。 但是你可以使用keyword? 如果您希望这成为他们的行为，那么也可以在 replace-self 中：

(defn replace-self
  [coll]
  (walk/prewalk
   (fn [form]
     (if (map? form)
       (reduce-kv
        (fn [acc k v]
          (assoc acc k (if (keyword? v)
                         (v form)
                         v)))
        {}
        form)
       form))
   coll))

(replace-self
 (edn/read-string
  "[{:abc \"value1\"
     :def :abc}
    {:abc {:bbb \"value2\"
           :def :bbb}
     :def :abc
     :xyz {:aaa \"value3\"
           :nope :abc
           :def :aaa}}]"))

这将返回与之前相同的结果，只是不需要自定义标签和自我记录：

[{:abc "value1", :def "value1"}
 {:abc {:bbb "value2", :def "value2"},
  :def {:bbb "value2", :def "value2"},
  :xyz {:aaa "value3", :nope nil, :def "value3"}}]