避免在缺少“匹配”实体的情况下输出属性

Question

XSLT 执行后，我有一张图片（一些属性为空值）

  <Document
            Region="Earth"
            City="Tokio"
            District=""
            Street="" >
  </Document>

我的 XSLT 是

<xsl:template match="Document">
     <Document
            Region="{Region/@attr1}" 
            City="{City/@attr2}"  
            District="{District/@attr3}"  
            Street="{Street/@attr4}"  >
      <xsl:apply-templates />
    </Document>
  </xsl:template>

所有 Xpathes 都是正确的。 问题是，正如我想的那样，我的代码太“直接”了。 需要更多的灵活性。 简而言之，符合条件：“如果源 XML 中没有要捕获的值\\属性，则输出节点中不应有任何相应的记录”。 在示例代码 {District/@attr3} 和 {Street/@attr4} 中，Xpath\\Expression 可能会返回一些值，但有时不会（那时源节点中甚至没有属性）。 因此，当 {District/@attr3} 和 {Street/@attr4} 返回\\“匹配”时，所需的输出必须如下所示：

期望输出

  <Document 
            Region="Earth"
            City="Tokio" >
  </Document>

如何改进 XSLT 代码 (1.0)？

Answer 1

前面的答案很好，但对于不太熟悉 XSLT 的人来说更难理解。 我只会添加 if 语句来测试该节点是否存在于源文档中。

<xsl:template match="Document">
  <xsl:element name="Document"/>
    <xsl:attribute name="Region" select="Region/@attr1"/>
    <xsl:attribute name="City" select="City/@attr2"/>
    <xsl:if test="District/@attr3">
      <xsl:attribute name="District" select="District/@attr3"/>
    </xsl:if>
    <xsl:if test="Street/@attr4">
      <xsl:attribute name="Street" select="Street/@attr4"/>
    </xsl:if>
      <xsl:apply-templates />
  </xsl:element>
</xsl:template>

你也可以更换

<xsl:element name="Document"/> with <xsl:copy>

Answer 2

如果没有看到更广泛的图景，就很难提出建议。 尝试类似：

<xsl:template match="Document">
    <Document
            Region="{Region/@attr1}" 
            City="{City/@attr2}" >
        <xsl:apply-templates select="District/@attr3 | Street/@attr4"/>
        <xsl:apply-templates/>
    </Document>
</xsl:template>

<xsl:template match="District/@attr3">
    <xsl:attribute name="District">
        <xsl:value-of select="."/>
    </xsl:attribute>
</xsl:template>

<xsl:template match="Street/@attr4">
    <xsl:attribute name="Street">
        <xsl:value-of select="."/>
    </xsl:attribute>
</xsl:template>

也许：

<xsl:template match="Document">
    <Document
            Region="{Region/@attr1}" 
            City="{City/@attr2}" >
        <xsl:apply-templates select="District/@attr3 | Street/@attr4"/>
        <xsl:apply-templates/>
    </Document>
</xsl:template>

<xsl:template match="District/@attr3 | Street/@attr4">
    <xsl:attribute name="{name(..)}">
        <xsl:value-of select="."/>
    </xsl:attribute>
</xsl:template>

未经测试，因为没有提供测试输入。

---

请注意，这假设属性要么有值，要么根本不存在——而不是它们是空的。 如果它们可以为空，则需要添加谓词，例如：

<xsl:apply-templates select="(District/@attr3 | Street/@attr4)[string()]"/>