CLIPS 中的语法

Question

我必须在 CLIPS 中实现一个专家系统，该系统使用的语法可以生成：

• 我看到了一个教程。
• 我去了一个图书馆。
• 在图书馆我看到了一个教程。
  我收到来自用户的输入 - 让我们假设它是第一句话 - 我必须打印一条消息，如：YES G1 G4 G3 G8，如果我可以用我的系统解析输入或否，否则。

---

为了实现这一点，我找到了一个模型系统，实现如下：
（歪曲事实
（规则 G1 S i B）
（E 中的规则 G2 S）
（规则 G3 B a C）
（规则 G4 B 锯 B）
（规则 G5 B 变为 S）
（规则 G6 B 锯 #）
（规则G7 B#）
（规则 G8 C 教程#）
（规则 G9 D i B）
（规则 G10 E 库 B）
（规则 S））

---

现在，我不知道如何实施规则，我正在寻求帮助。

谢谢！

Answer 1

         CLIPS (6.31 6/12/19)
CLIPS> 
(deftemplate sentence
   (multislot words)
   (multislot queue)
   (multislot rules)
   (slot symbol (default S)))
CLIPS>       
(deffacts productions
   (rule G1 S i B) 
   (rule G2 S in E) 
   (rule G3 B a C) 
   (rule G4 B saw B) 
   (rule G5 B went S) 
   (rule G6 B saw #) 
   (rule G7 B #) 
   (rule G8 C tutorial #) 
   (rule G9 D i B) 
   (rule G10 E a library B))
CLIPS>    
(deffacts test
   (sentence (words i saw a tutorial))
   (sentence (words i went in a library))
   (sentence (words in library a tutorial i saw)))
CLIPS>              
(defrule load-queue
    ?f <- (sentence (words ?w1 $?w2)
                    (queue)
                    (symbol S))
    =>
    (modify ?f (queue ?w1 $?w2)))
CLIPS>     
(defrule apply
   (rule ?r ?s $?m ?ns)
   (sentence (words $?w)
             (symbol ?s)
             (queue $?m $?e)
             (rules $?rules))
   =>
   (assert (sentence (words ?w)
                     (symbol ?ns)
                     (queue ?e)
                     (rules ?rules ?r))))
CLIPS>    
(defrule success 
   (declare (salience -10))
   (sentence (words $?w)
             (symbol #)
             (queue)
             (rules $?r))
   =>
   (printout t "YES " (implode$ ?w) " : " (implode$ ?r) crlf))
CLIPS> 
(defrule failure 
   (declare (salience -10))
   (sentence (words $?w) (queue $?w))
   (not (sentence (words $?w) (queue) (symbol #)))
   =>
   (printout t "NO  " (implode$ ?w) crlf))
CLIPS> (reset)
CLIPS> (run)
YES i saw a tutorial : G1 G4 G3 G8
YES i went in a library : G1 G5 G2 G10 G7
NO  in library a tutorial i saw
CLIPS>