如何在循环中使用变量引用控件？

Question

我有名为： label1 , label2 , ... label16 。 我想为所有人分配一个随机数。

这样的事情可以工作，但我不知道语法：

for i = 1 to 16
        label(i).text = Math.Ceiling(Rnd() * 99)
next

您的建议将不胜感激。

Answer 1

您可以使用Controls.Find使用它：

For i As Integer = 1 To 16
    Dim arrCtrl() As Control = Me.Controls.Find("label" & i, True)

    If arrCtrl.Length = 1 AndAlso TypeOf arrCtrl(0) Is Label Then
        DirectCast(arrCtrl(0), Label).Text = Math.Ceiling(Rnd() * 99)
    End If
Next

Answer 2

获取随机整数

---

在Random.Next(Int32, Int32)方法中使用Random类而不是Rnd函数获取指定范围内的随机Integer 。 声明一个Random类型的类变量：

Private ReadOnly rand As New Random

查找一系列控件

---

此代码片段迭代容器的Controls集合，返回（如果有） Label控件，其中它们的名称等于从label1到label16的名称范围，最后，将随机Integer分配给它们的Text属性：

Private Sub TheCaller()
    For Each lbl In Controls.OfType(Of Label).
        Where(Function(x) Enumerable.Range(1, 16).
        Any(Function(y) x.Name.ToLower.Equals($"label{y}")))
        lbl.Text = rand.Next(1, 100).ToString
    Next
End Sub

以防万一，如果Label控件由不同的容器托管，那么您需要一个递归函数来获取它们：

Private Function GetAllControls(Of T)(container As Control) As IEnumerable(Of T)
    Dim controls = container.Controls.Cast(Of Control)

    Return controls.SelectMany(Function(x) GetAllControls(Of T)(x)).
        Concat(controls.OfType(Of T))
End Function

并按如下方式调用它：

Private Sub TheCaller()
    For Each lbl In GetAllControls(Of Label)(Me).
        Where(Function(x) Enumerable.Range(1, 16).
        Any(Function(y) x.Name.ToLower.Equals($"label{y}")))
        lbl.Text = rand.Next(1, 100).ToString
    Next
End Sub

Answer 3

Private Sub Button2_Click(sender As Object, e As EventArgs) Handles Button2.Click
    Dim labels As New List(Of Label) From {Label1, Label2, Label3, Label4}
    For Each l As Label In labels
        l.Text = rand.Next(99).ToString
    Next
End Sub

使用你的方法

1. 在方法之外为 Random 类声明一个变量（表单级别变量）。

2. 创建标签列表。

3. 循环遍历列表中的所有标签，并使用 Random 类的 .Next 方法设置 .Text 属性。