在用户窗体初始化上设置多个复选框

Question

这里是新的（第一篇文章），对 vba excel 也很新，我遇到了一个我正在努力解决的绊脚石。 如果我能在这里找到帮助，那我将非常感激！

我有一个包含 90 个复选框的用户表单。 在表单初始化时，我想根据特定工作表上的单元格中包含的值将所有复选框设置为 TRUE 或 FALSE，我可以这样做，我现在必须为另外 89 个复选框执行此操作，其中当前的格式将变得笨拙。

我正在寻找有关如何以更简洁的方式实现这一目标的建议。

谢谢！

Private Sub UserForm_Initialize()

    Dim chRange As Range
    Dim ws As Worksheet
    Dim PDI_No As String
    Dim Row As Integer
    Dim rfind1 As Range
    Dim Col_Ltr1 As String

    Set ws = Worksheets("Master_Log")
    Set chRange = ws.Range("A:A")
    PDI_No = UpdateRecord.ComboBox1.Value
    Row = Application.WorksheetFunction.Match(PDI_No, chRange, 0) 'finds row number
    With Worksheets("Master_Log").Range("A1:DZ1")
        Set rfind1 = .find(What:=CheckBox1.Caption, LookAt:=xlWhole, MatchCase:=False, 
                      SearchFormat:=False) 'finds column number
       Col_Ltr1 = Split((Columns(rfind1.Column).Address(, 0)), ":")(0) 'changes column number to a 
                  letter
       cellposition1 = Col_Ltr1 & Row 'range value

            If ws.Range(cellposition1) = CheckBox1.Caption Then
                CheckBox1.Value = True
                    Else
                CheckBox1.Value = False
            End If
        End With
End Sub

Answer 1

您可以执行以下操作（假设您的复选框都具有一致的名称）：

Private Sub UserForm_Initialize()

    Dim ws As Worksheet
    Dim PDI_No As String
    Dim theRow, theCol, i As Long, cb As Object

    Set ws = Worksheets("Master_Log")
    PDI_No = UpdateRecord.ComboBox1.Value
    theRow = Application.Match(PDI_No, ws.Range("A:A"), 0) 'finds row number

    If Not IsError(theRow) Then
        For i = 1 To 90
            Set cb = Me.Controls("CheckBox" & i) '<<<<<
            theCol = Application.Match(cb.Caption, ws.Range("A1:DZ1"), 0)
            If Not IsError(theCol) Then
                cb.Value = (ws.Cells(theRow, theCol).Value = cb.Caption)
            Else
                'no column match
            End If
        Next i
    Else
        'no row match...
    End If

End Sub

Answer 2

您可以循环浏览用户窗体上的所有控件，特别是寻找复选框，如下所示：

Private Sub CycleThroughCheckboxes
Dim x As Control
Dim r As Long
Dim result as Boolean
For Each x In UserForm1.Controls
    If TypeName(x) = "CheckBox" Then
        x.Value = true ' or false - Do your find logic here using x.Caption
    End If
Next x
End Sub

这样做的好处是，如果您添加/删除了一些复选框，则无需在以后继续计数和更改代码。

Answer 3

我不喜欢相信所有 90 个复选框都以连续数字命名的想法。 以下循环将遍历表单的所有控件并检查类型。

Dim ctrl As Control
For Each ctrl In Me.Controls
    if TypeName(ctrl) = "CheckBox" then
        ' rest of the logic "stolen" from Ted Willams answer:
        theCol = Application.Match(ctrl.Caption, ws.Range("A1:DZ1"), 0)
        If Not IsError(theCol) Then
            ctrl.Value = (ws.Cells(theRow, theCol).Value = ctrl.Caption)
        Else
            'no column match
        End If
    End If
Next ctrl