awk 浮点比较不起作用

Question

我有带有 x1、x2 和 x 值的输入文件，我想检查 x 是否是 x1 和 x2 之间的中点。 但是比较失败了。

样本输入文件

x1=20.9280 x2=20.9600 x=20.9440
x1=20.9280 x2=20.9600 x=20.9440
x1=22.7840 x2=22.8160 x=22.8000

Awk 命令

awk -F'[ =]' '{ if(($2 + $4)/2 != ($6)) print ($2 + $4)/2, " ", $6;}' sample

OUTPUT

20.944   20.9440
20.944   20.9440
22.8   22.8000

由于小数点后有多余的零，比较失败。 请帮助修复它。

Answer 1

这是由于所有平台中普遍存在的浮点比较问题而发生的。

您可以将此awk用于浮点数比较，方法是将数字转换为具有 4 个小数点的浮点数：

awk -F'[ =]+' '{avg = sprintf("%.4f", ($2 + $4) / 2)} avg != $6 { print avg, $6 }' file

---

如果您有gnu awk那么您可以将精度设置为较低的数字：

awk -M -v PREC=30 -F'[ =]+' '{avg = ($2 + $4) / 2; $6 += 0} avg != $6 { print avg, $6 }' file

Answer 2

不是真正的anwser，但确实展示了。 您正在比较浮点数，它们不相等。 我用printf和具有足够小数的修饰符（20， %.20f ）替换了print ：

$ awk -F'[ =]' '{
    if(($2 + $4)/2 != ($6)) 
        printf "%.20f %.20f\n", ($2 + $4)/2, $6
}' file

输出：

20.94400000000000261480 20.94399999999999906208
20.94400000000000261480 20.94399999999999906208
22.79999999999999715783 22.80000000000000071054

所以使用sprintf和适当的修饰符（参见我使用的printf ）来控制这些值。

Answer 3

正如其他人指出的那样，如果您遇到问题，那么您可能只是遇到了常见的浮点算术问题，但由于您的所有输入值都具有相同的精度，您可以摆脱. s 将输入数字视为整数并乘以 2 而不是除以 2 只是为了将其保持为 integer 比较：

$ awk -F'[ =]' '{o=$0; gsub(/\./,"")} ($6*2) == ($2+$4){$0=o; print ($2+$4)/2, $6}' file
20.944 20.9440
20.944 20.9440
22.8 22.8000

$ awk -F'[ =]' '{o=$0; gsub(/\./,"")} ($6*2) != ($2+$4){$0=o; print ($2+$4)/2, $6}' file
$