求解线性方程组

Question

我有两个（数学）函数：

y = x
y = -2x + 3

这可以通过y = 1和x = 1解决。 见图片：

我怎样才能让 Julia 为我做这个？

Answer 1

这是一组线性方程，因此首先按以下方式重新排列它们：

-x + y = 0
2x + y = 3

你会看到它们是线性方程组A*v=b的形式，其中。 A是一个矩阵：

julia> A = [-1 1; 2 1]
2×2 Array{Int64,2}:
 -1  1
  2  1

b是一个向量：

julia> b = [0, 3]
2-element Array{Int64,1}:
 0
 3

现在v包含您的未知变量x和y 。 您现在可以使用左除法运算符\求解系统：

julia> A\b
2-element Array{Float64,1}:
 1.0
 1.0

如果你有一个更一般的非线性方程组，你应该使用 NLsolve.jl package：

julia> using NLsolve

julia> function f!(F, v)
           x = v[1]
           y = v[2]
           F[1] = -x + y
           F[2] = 2*x + y - 3
       end
f! (generic function with 1 method)

julia> res = nlsolve(f!, [0.0; 0.0])
Results of Nonlinear Solver Algorithm
 * Algorithm: Trust-region with dogleg and autoscaling
 * Starting Point: [0.0, 0.0]
 * Zero: [1.0000000000003109, 0.9999999999999647]
 * Inf-norm of residuals: 0.000000
 * Iterations: 2
 * Convergence: true
   * |x - x'| < 0.0e+00: false
   * |f(x)| < 1.0e-08: true
 * Function Calls (f): 3
 * Jacobian Calls (df/dx): 3

julia> res.zero
2-element Array{Float64,1}:
 1.0000000000003109
 0.9999999999999647

（请注意，在f!中，我们将两个输出F[1]和F[2]定义为零 - 你必须以这种方式重新排列你的方程）。

有关如何使用 NLsolve.jl 的更多详细信息，请参阅https://github.com/JuliaNLSolvers/NLsolve.jl 。

Answer 2

@bogumił-kamiński先生给出了很好的答案。 但是，只是一个友好的提醒，对于其他一些线性方程组，解决方案可能不存在。 在这种情况下，你会得到一个SingularException 。 考虑检查解决方案是否存在。 例如，

using LinearAlgebra;
"""

y = x         =>     x - y = 0  =>    |1  -1| X = |0|  => AX = B => X = A⁻¹B     
y = -2x + 3          2x + y = 3       |2   1|     |3|
"""

function solution()
  A::Matrix{Int64} = Matrix{Int64}([1 -1; 2 1]);
  
  br::Matrix{Int64} = Matrix{Int64}([0 3]);
  bc = transpose(br);

  # bc::Matrix{Int64} = Matrix{Int64}([0 ;3;;]);   # I missed a semicolon, that's why I got an error
  # println(bc);

  if(det(A) == 0)    # existence check
    println("soln doesnot exist. returning...");
    return
  end
  A⁻¹ = inv(A);
  println("solution exists:")
  X = A⁻¹ * bc;
  println(X);

end

solution();