Pine Script 中的 RSI Ping-Pong 指标

Question

我想使用“RSI-Ping-Pong-Indicator”作为其他条件回测的先决条件。 为此，我定义了一个 RSI 和一个 RSI 多空区域，例如 rsi(25) = long 和 rsi(75) = short。

rsiShortLevel = input(75, title="RSI Short Level")
rsiLongLevel = input(25, title="RSI Long Level")

如果 RSI 跌至 ( crossunder() ) 低于多头区域 (rsi < 25)，则指标应切换为“多头”。 指标保持“多头”，直到 RSI 下一次达到 ( crossover() ) 空头区域 (rsi > 75)，然后指标切换到“空头”。 反之亦然，例如“RSI Ping-Pong”。 在多头交叉和下一个空头交叉之间，RSI 可以多次重新交叉多头，并且可以在这个“中间区域”中移动很长时间，但它会保持“多头”，直到 RSI 交叉短期水平。

然后我可以 plot 将交叉条件与pingpong条件作为蓝线。 为了在 Tradingview 中更好地直观理解，以下多空条件显示“多头”的多头水平 ( rsiLongLevel = 25) 和“空头”的空头水平 ( rsiShortLevel = 75) 的值：

///RSI Crossings
rsiLongCondition = crossunder(rsi, rsiLongLevel)
rsiShortCondition = crossover(rsi, rsiShortLevel)

///RSI Ping-Pong
pingpong = if(rsiLongCondition)
    rsiLongLevel
else
    if(rsiShortCondition)
        rsiShortLevel

plot(showPingpong ? pingpong : na, color=color.blue, style=plot.style_line, linewidth=2, title='RSI Ping-Pong')

但是，很明显，25 或 75 的值仅在实际交叉处是 output，而不是在交叉口之间：在交叉口之间，值为na 。

现在我想实现长交叉后的值继续 output 值（这里：25 又名“长”），直到短区域被越过并且值变为 75（又名“短”）。

如果我使用技巧并将“strategy.entry”和“strategy.position_size”发挥作用并将它们链接到iff-condition，我可以显示此行为：

if(rsiLongCondition)
    strategy.entry(id="LE-RSI-Cross", long=true, qty=1)
if(rsiShortCondition)
    strategy.entry(id="SE-RSI-Cross", long=false, qty=1)

pingpongPositionSize = iff(strategy.position_size > 0, rsiLongLevel, iff(strategy.position_size < 0, rsiShortLevel, na))

如果我 plot 变量pingpongPositionSize （黑线）并设置背景颜色条件（红色 = 短，绿色 = 长），指示器正确显示相应的值和背景颜色：

plot(showPingpongSize ? pingpongPositionSize : na, color=color.black, style=plot.style_line, linewidth=4, title='RSI-Position-Size Ping-Pong')
bgcolor(showBGSize and strategy.position_size > 0 ? color.green : showBGSize and strategy.position_size < 0 ? color.red : na, transp=70)

我的问题：如何构建我想要的指标，使其行为与“strategy.position_size”技巧相同？

完整脚本

/@version=4
strategy("RSI Ping-Pong", overlay=false)

// GENERAL SETTINGS

rsiLenght = input(14, title="RSI Lenght")
rsiShortLevel = input(75, title="RSI Short Level")
rsiLongLevel = input(25, title="RSI Long Level")
showBGCrossings = input(false, title="Show RSI-Crossings with bgcolor?")
showPingpong = input(true, title="Show RSI Ping-Pong?")
showPingpongSize = input(true, title="Show RSI-Position-Size Ping-Pong?")
showBGSize = input(true, title="Show RSI Position Size Changes with bgcolor?")


// CALCULATIONS
rsi = rsi(close, rsiLenght)

///RSI Crossings
rsiLongCondition = crossunder(rsi, rsiLongLevel)
rsiShortCondition = crossover(rsi, rsiShortLevel)

///RSI Ping-Pong
pingpong = if(rsiLongCondition)
    rsiLongLevel
else
    if(rsiShortCondition)
        rsiShortLevel

/// RSI Ping-Pong with Strategy Position Size
if(rsiLongCondition)
    strategy.entry(id="LE-RSI-Cross", long=true, qty=1)
if(rsiShortCondition)
    strategy.entry(id="SE-RSI-Cross", long=false, qty=1)

pingpongPositionSize = iff(strategy.position_size > 0, rsiLongLevel, iff(strategy.position_size < 0, rsiShortLevel, na))

// PLOTTING
plot(rsi, color=color.purple, style=plot.style_line, linewidth=2, title='RSI')
plot(showPingpong ? pingpong : na, color=color.blue, style=plot.style_line, linewidth=2, title='RSI Ping-Pong')
bgcolor(showBGCrossings and rsiLongCondition ? color.green : rsiShortCondition ? color.red : na, transp=0)
plot(showPingpongSize ? pingpongPositionSize : na, color=color.black, style=plot.style_line, linewidth=4, title='RSI-Position-Size Ping-Pong')
bgcolor(showBGSize and strategy.position_size > 0  ? color.green : showBGSize and strategy.position_size < 0 ? color.red : na, transp=70)
hlong = hline(rsiLongLevel, title="RSI Long Level")
hshort = hline(rsiShortLevel, title="RSI Short Level")

Answer 1

利用：

///RSI Ping-Pong
var pingpong = 0.
if(rsiLongCondition)
    pingpong := rsiLongLevel
else
    if(rsiShortCondition)
        pingpong := rsiShortLevel

var初始化仅初始化第一个柱上的变量，其值仅在交叉时更改，因此其值在更改后跨柱传播。 请参阅有关该主题的 usrman 。