XSLT：基于属性值的总和

Question

我有这个文档，我想使用 XSLT 转换为 HTLM 文档。 我想按城市总结价格，这意味着我将拥有以下 output：

Chicago 89
New York 144
Washington 147 
Philadeplhia 73

XML 输入

<?xml version="1.0" encoding="ISO-8859-1" ?>
<?xml-stylesheet href="class.xsl" type="text/xsl" ?>
<root>
<person><name>John</name>
<property city="Chicago" price="89" />
<property city="New York" price="69" />
<property city="Washington" price="75" /></person>
<person><name>Mike</name>
<property city="New York" price="75" />
<property city="Washington" price="72" />
<property city="Philadeplhia" price="73" /></person>
</root>

我以为我可以使用 generate.id 为每个城市生成一个唯一 ID，然后生成一个sum() ，但它不起作用：

<xsl:value-of select="root/person/property/@city" /> 
<xsl:value-of select="generate-id(.)" />)

Answer 1

也许这可以帮助您找到解决方案（XSLT 2.0）：

<xsl:for-each-group select="//property" group-by="@city">
     <xsl:value-of select="sum(current-group()/@price)"/>
</xsl:for-each-group>

Answer 2

问题解决了： ：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="text"/>
  <xsl:strip-space elements="*"/>

  <xsl:key name="property_by_city" match="property" use="@city"/>

  <xsl:template match="/">
    <xsl:for-each select="//property[count(.|key('property_by_city',@city)[1])=1]">
      <xsl:value-of select="concat(@city,' ',sum(key('property_by_city',@city)/@price),'&#xA;')"/>
    </xsl:for-each>
  </xsl:template>
  
</xsl:stylesheet>