在 SAS 中，如何获得对每个个体具有多个观察值的变量的不同计数？

Question

一个简单的问题，但我的数据集中有三个变量：ID、ICDCode 和访问日期。 每个人（ID）的每个 ICDCode 多次出现。 如何获得整个数据集的 icdcode 的总、不同的计数，而不为个人计算两次特定的 ICDCode？ 例如，我想说我的数据集中有 100 例心脏病（同一个人不计算 10 次心脏病）。
以下是我尝试过的代码：

    proc freq data= cases;
    table ICDCode;
    run;

    proc sql;
    select ICDCode,
    count(*) as Frequency
    from cases
    group by ID;
    quit;
    

Answer 1

简单地说：（鉴于 429.9 代表心脏病）

data cases;
input ID ICDCode;
datalines;
1 429.9
1 429.9
1 2    
1 3    
3 429.9
3 429.9
3 3    
2 1    
2 2    
;

proc sql;
   select count(distinct ID) as n
   from cases
   where ICDCode = 429.9;
run;

Answer 2

按 icd 代码分组时计算不同的患者 ID。

例子：

data have;
  call streaminit(123);
  do patid = 1 to 100;
    do dxseq = 1 to 10;
      if rand('uniform') < 0.25 or dxseq = 1 then 
        code = '429.9';  /* hey Oprah, everybody gets a heart disease!; */
      else
        code = put(428 + round(3*rand('uniform'),0.1), 5.1);
      output;
    end;
  end;
run;

proc sql;
  create table codefreq as
    select code, count(distinct patid) as pat_count
    from have
    group by code;

Answer 3

首先使用 nodupkey 进行排序以限制每个观察到的 ID/ICDcode 组合的一个副本，然后运行一个简单的频率表。

proc sort data=cases out=want nodupkey;
   by id icdcode;

proc freq data=want;
   tables icdcode;
run;