Windows 批处理 - 在具有特定名称的文件夹中查找图像文件

Question

我正在尝试编写一个 windows 批处理脚本，它可以 select 以某个字符串开头的目录中的所有.bmp文件。

目录结构示例：

c:\root
 |- images
     |- 2020-08-19
         |- 001-ABC
         |   |- firstfile.bmp
         |   |- secondfile.bmp
         |
         |- 002-DEF
             |- thirdfile.bmp
             |- fourthfile.bmp

我希望能够对以001-开头的文件夹中的所有.bmp文件执行命令（在这种情况下：转换为 JPG）

因此，在上面的示例中，将选择执行以下文件：

c:\root\images\2020-08-10\001-ABC\firstfile.bmp
c:\root\images\2020-08-10\001-ABC\secondfile.bmp

我能够找到所需的文件夹，但无法弄清楚如何执行 rest：

forfiles /P c:\root\images /S /M 001-*

如何在这些文件夹中找到所有.bmp文件，然后执行转换？
（注：我已经知道执行命令）

Answer 1

例如，使用外部for /d循环来迭代所有需要的文件夹，并使用内部for循环来迭代.bmp文件：

@echo off

set "_root_=c:\root\images\2020-08-10"
set "_prefix_=001-"

for /d %%A in ("%_root_%\%_prefix_%*") do (
  for %%B in ("%%A\*.bmp") do (
    echo processing '%%B'...
  )
)

更新。

或与单线相同：

forfiles /p "c:\root\images\2020-08-10" /m "001-*" /s /c "cmd /c @for %A in ("@path\*.bmp") do @echo processing '%A'..."

Answer 2

@ECHO OFF
SETLOCAL
SET "sourcedir=U:\sourcedir"
SET "dirprefix=001-"
SET "datestring=2020-08-19"
FOR /f "tokens=*delims=" %%a IN (
 'dir /s /b /a-d "%sourcedir%\*.bmp" ^|find /i "%sourcedir%\%datestring%\%dirprefix%"'
 ) DO (
ECHO process "%%~a"
)
GOTO :EOF

您需要更改sourcedir的设置以适应您的情况。 该清单使用适合我的系统的设置。

处理是：执行一个dir以基本形式列出所有“.bmp”文件的子目录（它以绝对格式列出所有必需的文件），然后使用for过滤所需的字符串，并使用/i使过滤器不区分大小写。

然后使用for/f和delims=处理结果列表，将整行分配给%%a 。