代表管道的函数列表的类型化 Racket 类型

Question

我在无类型 Racket 中有一个 function，它采用代表输入的 arguments、代表管道的函数和符号列表以及停止应用函数的符号（我知道这不是很清楚，但代码在下面）。 我正在尝试将其转换为 Typed Racket，但无法弄清楚如何让类型系统了解正在发生的事情。 我知道我可以使用cast来强制它工作，但我想知道是否有更好的方法？

(define (apply-steps on steps stop-symbol)
  (match steps
    ['() on]
    [(cons step rst)
     (cond
       [(equal? stop-symbol (car step)) ((cadr step) on)]
       [else (apply-steps ((cadr step) on) rst stop-symbol)])]))

我需要以某种方式指定签名的类型，例如：

(apply-steps [on : T1] 
             [steps : (List (Pairof Symbol (-> T1 T2)) (Pairof Symbol (-> T2 T3)) ... (Pairof Symbol (-> Tn-1 Tn))]
             [stop-symbol : Symbol]) : Tn

谢谢！

Answer 1

有几个问题：

• 您的输入之一本质上是一个函数列表。 您希望它具有类型(List (-> F1 F2) (-> F2 F3)... (-> Fn Fn+1)) ，但我不认为 Typed Racket 可以支持这种事情。 如果你写出来，它涉及无限数量的类型变量，取决于列表的长度？ 你怎么能有限地指定类型。[1]。

  要解决此问题，我建议您将要求更改为(List (-> AA) (-> AA)... (-> AA)) = (Listof (-> AA)) 。

• 根据给定的类型，每个元素都是一个(Pairof Function Symbol) ，但是从您的 function 来看，它看起来需要一个(List Symbol Function) （当我试用您的程序时，这是由 Typed Racket 捕获的）。

应用修复程序，您将获得：

(: apply-steps (All (A) (-> A (Listof (List Symbol (-> A A))) Symbol A)))
(define (apply-steps on steps stop-symbol)
  (match steps
    ['() on]
    [(cons step rst)
     (cond
       [(equal? stop-symbol (car step)) ((cadr step) on)]
       [else (apply-steps ((cadr step) on) rst stop-symbol)])]))

顺便说一句，如果你使用常规的 Racket，你也可以使用for/fold和#:final子句来实现这个 function。

(define (apply-steps on steps stop-symbol)
  (for/fold ([on on]) ([step (in-list steps)])
    (match-define (list sym f) step)
    #:final (equal? stop-symbol sym)
    (f on)))

不幸的是，Typed Racket（还）不支持#:final ，所以你不能在这里使用它。

[1]：好的，所以一种可能性可能是：对于列表中的任何两个相邻元素，对于某些A 、 B 、 C ，它们必须是(-> AB)和(-> BC) 。 不过，我不认为 Typed Racket 可以支持像这样的任意高阶谓词。