在自己的首字母目录中移动文件夹

Question

我使用此脚本将文件夹移动到它们自己的首字母目录中

@echo off
setlocal enabledelayedexpansion

tree
for /d %%i in (*) do (
  set first=%%i
  set first=!first:~0,1!
  md !first! 2>nul
  if not "!first!" == "%%i" move "%%i" "!first!\%%i" 
)
tree

首字母目录由此脚本生成。 例如，如果我有这样的文件夹名称

Wachenfeldt - The
Пламень - Чужие
Von Stroheim - Lov

此脚本生成的第一个字母目录可能是

W
П
V

如果第一个字母目录之前已经存在，我不测试这个脚本

为什么会出现问题？ 脚本部分起作用是因为许多文件夹没有移动到它们自己的首字母目录中，而是移动到 CMD 我读到了这个错误消息：

文件名或扩展名太长

移动的文件夹名称示例

Wachenfeldt - The Interpreter (2019) Progressive Death Metal
Whitby Bay - Gothic Attack Vehicle (2018) Black Metal
Пламень - Чужие (2017) Black Metal (D5)

W
|
|----  Wachenfeldt - The Interpreter....
|----- Whitby Bay - Gothic Attack....

П
|
|----- Пламень - Чужие (20...

未移动的文件夹名称示例（脚本不适用于它们）

Withering Night - Within The Shadows We Lurk (2013) Black Metal (D5)
Woltemade - Siele Vir Die See (2019) Melodic Death Metal
Von Stroheim - Love_ Who Gets Love_ (2019) Doom_Post-Metal

Answer 1

我建议为此文件夹移动任务使用以下批处理代码：

@echo off
setlocal EnableExtensions DisableDelayedExpansion
%SystemRoot%\System32\tree.com
for /F "eol=| delims=" %%I in ('dir /AD /B 2^>nul') do (
    set "FolderName=%%I"
    setlocal EnableDelayedExpansion
    set "TargetFolder=!FolderName:~0,1!"
    if not "!TargetFolder!" == "!FolderName!" (
        md "!TargetFolder!" 2>nul
        move /-Y "!FolderName!" "!TargetFolder!\"
    )
    endlocal
)
%SystemRoot%\System32\tree.com
endlocal

对于将文件夹移动到子文件夹的这项任务，最重要的是首先将整个文件夹名称列表加载到 memory 中，然后再使用FOR循环处理每个文件夹名称。 仅for /d %%i in (*) do ，命令FOR会遍历文件夹名称列表，直接从文件系统中按名称获取名称，并且该列表会随着循环内命令的每次执行而更改，因为创建也许是一个额外的文件夹并将一个文件夹移动到一个子文件夹中。 这很容易导致一个文件夹被处理多次（这里没问题），或者由于当前文件夹中的文件夹更改而被跳过，而FOR遍历列表。 特别是在 FAT32 和 exFAT 驱动器上，目录条目未按字母顺序本地特定排序，首先获取加载到 memory 的完整文件夹列表，然后开始迭代 memory 中不受影响的列表中的文件夹非常重要通过在循环中执行命令期间文件系统中的修改。

带有选项/F的FOR导致在后台启动另一个命令进程，其中%ComSpec% /c和'中的命令行附加为附加 arguments。 所以执行是在后台安装 Windows 到C:\Windows ：

C:\Windows\System32\cmd.exe /c dir /AD /B 2>nul

后台命令进程执行的命令DIR在当前目录中搜索

• 只是因为选项/AD （属性目录）的文件夹，包括被for /D忽略的隐藏属性集的文件夹和
• 由于选项/B ，仅以裸格式输出没有路径的文件夹名称。

阅读有关使用命令重定向运算符的 Microsoft 文档，了解2>nul的说明。 当 Windows 命令解释器在执行命令FOR执行嵌入式dir命令行并使用在后台启动的单独命令进程之前处理此命令行时，重定向运算符>必须在FOR命令行上使用脱字符^进行转义以解释为文字字符。

为处理已启动命令进程的STDOUT而编写的 output 由正在处理批处理文件的命令进程捕获，并在已启动的命令进程在完成命令DIR执行后自行终止后由FOR逐行解释。

带有选项/F的FOR默认忽略空行，这在这里没有问题。 默认情况下，使用普通空格和水平制表符作为字符串分隔符将一行拆分为子字符串。 使用delims=禁用该行拆分行为，它定义了一个空的分隔符列表，因为文件夹名称可以包含一个或多个空格。 如果第一个 substring（在这种情况下为整行）以默认的行尾字符开头，则该行也会被忽略; 这里不需要，因为文件夹名称可以以分号开头。 eol=| 将行尾字符重新定义为竖线，任何文件夹名称都不能包含? 或*也可以使用。

将当前文件夹名称分配给环境变量时未启用延迟扩展，因为否则文件夹名称包含一个或多个! 批处理文件不会正确处理。 如果在处理此命令行时已启用延迟环境变量扩展，则 Windows 命令处理器会将文件夹名称中的感叹号解释为命令行set "FolderName=%%I"上延迟扩展环境变量引用的开始/结束。

另请参阅： Windows 命令解释器 (CMD.EXE) 如何解析脚本？

但是有必要为进一步的命令启用延迟扩展，例如变量描述的行为不符合预期，因此命令setlocal EnableDelayedExpansion现在用于启用延迟扩展。

重要的是在以下命令行中始终引用具有延迟扩展的环境变量FolderName ，并且不要使用%%I来处理带有一个或多个感叹号的正确文件夹名称。

如果当前文件夹名称已经不是单字符文件夹名称，则将当前处理的文件夹移动到名称为当前文件夹名称第一个字符的子文件夹中，当然目标文件夹的创建完全成功并且当前文件夹可以真正移动，因为没有正在运行的进程将此文件夹或其子文件夹之一用作当前文件夹，并且没有正在运行的进程在此文件夹或其子文件夹中打开任何文件，只要被进程和目标文件夹不包含同名文件夹。

然后在处理 memory 列表中的下一个文件夹名称之前，必须恢复之前的执行环境。 阅读此答案以了解有关命令SETLOCAL和ENDLOCAL的详细信息，因为除了为列表中的每个文件夹名称启用和禁用延迟扩展之外，还有更多工作要做。

要了解使用的命令及其工作原理，请打开命令提示符window，在其中执行以下命令，并仔细阅读每个命令显示的所有帮助页面。

• dir /?
• echo /?
• endlocal /?
• for /?
• if /?
• md /?
• move /?
• set /?
• setlocal /?
• tree /?

注意：此批处理文件解决方案不适用于包含 Unicode 字符的文件夹。 如果文件夹包含非ASCII字符，则应使用类似mklement0编写的PowerShell脚本。