Gnuplot：我可以在某些数据点上拉伸 x 轴吗？

Question

我有时间点向量，将在 x 轴上表示。
其中一些时间点出现在某个符号上，而其他时间点出现在不同的符号上。
我想将 x 缩放到 y 以作为 x=1:y=1 的第一个符号。
我想将 x 缩放到 y 作为第二个符号 x=2:y=1
这样我将有一个 x 轴在某些点拉伸的图形“x 单位 = 双倍空间，例如 2 厘米持续 1 小时”并在其他点收缩“x 单位 = 单倍空间，例如 1 厘米持续 1 小时”
我有与时间数组具有相同索引的数组，其中 1 用于单空间时间点，2 用于双空间时间点。
我可以在 gnuplot 中使用 plot 这个吗？ 更新：
如果在 gnuplot 中不可能，是否有任何其他库可以通过控制每个点的轴比例来绘制点？“一个数组用于每个点的轴比例，另一个用于轴数据？”
更新：
数据点：100 50 70 130 40 20 30 50 88 93
点宽：1 1 1 2 2 2 2 1 1 1
时间滴答：1 2 3 4 5 6 7 8 9 10
这些时间刻度应该在 x 轴上，但在 1 2 3 之间作为 1 个单位，例如 1 厘米，在 4 5 6 7 之间作为 2 个单位，例如 2 厘米，然后在 8 9 10 之间作为 1 个单位
数据点将是 1000000，随机 1 和 2 个单位部分。
我不知道如何绘制他们的图表。

Answer 1

我仍然不确定我是否完全理解，但这是我认为你可能想要的。 因此，您的事件仅从 1，... N 开始计数。这些事件不会以常规时间步长发生。 有时 1 秒后，有时 2 秒后。 为了 plot 这您只需总结所有这些时间差，例如在变量t中。

代码：

### add variable stepsize for x-values
reset session

$Data <<EOD
 1   1  100 
 2   1   50
 3   1   70
 4   2  130
 5   2   40
 6   2   20
 7   2   30
 8   1   50
 9   1   88
10   1   93
EOD

set grid x

plot t=0 $Data u (t):(t=t+$2,$3) w lp pt 7 notitle
### end of code

结果：

添加：

这是试图理解您的意思的另一种尝试。 这就是我现在从您的问题和评论中了解到的。 你有事件，它们之间的距离如下：1、2、3之间的距离应该是1，3、4、5、6、7之间应该是2，7、8、9、10之间应该是1。

# event    1   2   3   4   5   6   7   8   9   10
# distance   1   1   2   2   2   2   1   1   1

代码：（可以跳过plot命令的第二行，只是显示事件编号）

### add variable stepsize for x-values
reset session

$Data <<EOD 
 1   1  100
 2   1   50
 3   1   70
 4   2  130
 5   2   40
 6   2   20
 7   2   30
 8   1   50
 9   1   88
10   1   93
EOD

set grid x
set offsets 0,1,0,0

plot t=0 $Data u (t=t+$2):3 w lp pt 7 notitle, \
     t=0 ''    u (t=t+$2):3:1 w labels offset 0,1 notitle
### end of code

结果：