如何在 julia 中指定数组的第 i 个轴

Question

如何使用for循环简化代码？

eta和T是 6 阶张量 arrays 和size(eta) == size(T) 。

using  InvertedIndices
one_to_N = [1:6;]
eta[:,1,1,1,1,1] = vec(sum(T, dims=one_to_N[Not(1)]))
eta[1,:,1,1,1,1] = vec(sum(T, dims=one_to_N[Not(2)]))
eta[1,1,:,1,1,1] = vec(sum(T, dims=one_to_N[Not(3)]))
eta[1,1,1,:,1,1] = vec(sum(T, dims=one_to_N[Not(4)]))
eta[1,1,1,1,:,1] = vec(sum(T, dims=one_to_N[Not(5)]))
eta[1,1,1,1,1,:] = vec(sum(T, dims=one_to_N[Not(6)]))

Answer 1

除了创建总和然后将它们复制到eta中，您还可以直接使用sum! . 使用索引1:1而不是1创建视图意味着这些维度不会被删除，因此sum! 可以推断出要对哪些维度求和：

data = rand(Int8, 4,7,2);  # originally T, with ndims(T)==6, reduced for clarity
eta = ones(4,7,2);

for dim in 1:ndims(data)
    ind = ntuple(d -> d==dim ? (:) : (1:1), ndims(data))
    sum!(view(eta, ind...), data)
end

这给出了：

julia> eta
4×7×2 Array{Float64, 3}:
[:, :, 1] =
   -1.0  -29.0  -581.0  118.0  -106.0  189.0  198.0
 -100.0    1.0     1.0    1.0     1.0    1.0    1.0
  468.0    1.0     1.0    1.0     1.0    1.0    1.0
 -214.0    1.0     1.0    1.0     1.0    1.0    1.0

[:, :, 2] =
 -130.0  1.0  1.0  1.0  1.0  1.0  1.0
    1.0  1.0  1.0  1.0  1.0  1.0  1.0
    1.0  1.0  1.0  1.0  1.0  1.0  1.0
    1.0  1.0  1.0  1.0  1.0  1.0  1.0

julia> dim = 2;

julia> ind = ntuple(d -> d==dim ? (:) : (1:1), ndims(data))
(1:1, Colon(), 1:1)

julia> view(eta, ind...)
1×7×1 view(::Array{Float64, 3}, 1:1, :, 1:1) with eltype Float64:
[:, :, 1] =
 -1.0  -29.0  -581.0  118.0  -106.0  189.0  198.0

julia> sum(data, dims=(1,3))
1×7×1 Array{Int64, 3}:
[:, :, 1] =
 80  -29  -581  118  -106  189  198

请注意，这里eta[1]被多次覆盖，因此结果取决于操作的顺序，而不仅仅是data数组。

Answer 2

有很多方法可以做到这一点。 以下是一些很快浮现在脑海中的：

你可以这样做：

for i in 1:6
    eta[ifelse.(1:6 .== i, :, 1)...] = vec(sum(T, dims=one_to_N[Not(i)]))
end

或像这样：

for i in 1:6
    eta[ntuple(j -> j == i ? (:) : 1, 6)...] = vec(sum(T, dims=one_to_N[Not(i)]))
end

或像这样：

for i in 1:6
    eta[(j == i ? (:) : 1 for j in 1:6)...] = vec(sum(T, dims=one_to_N[Not(i)]))
end