As3 const 是否在编译或运行时初始化？

Question

我正在使用 ActionScript 并且我看到有可能使用 const 属性。

我有一个疑问：

• As3 const 属性是否在编译或运行时初始化？

Answer 1

好的，让我们用const ant 来解释一下事物的流程。 我设计了一个非常简单且不言自明的 class：

package 
{
    import flash.display.Sprite;
    
    public class Kunst extends Sprite
    {
        public const A:int = int(trace("Init A:", A, B, C, D)) + 10;
        public const B:String = initB() + String(trace("Init B:", A, B, C, D)) + initB();
        public const C:int = 10 + 10;
        
        static public const D:String = String(trace("Init D:", D, E, F)) + initD();
        static public const E:Boolean = initE() && Boolean(trace("Init E:", D, E, F)) || initE();
        static public const F:int = 10 + 10 + 10;
        
        public function Kunst() 
        {
            super();
            
            trace("Check ABC:", A, B, C);
            trace("Check DEF:", D, E, F);
        }
        
        private function initB():String
        {
            trace("Init B2:", A, B, C, D);
            return "B";
        }
        
        static private function initD():String
        {
            trace("Init D2:", D, E, F);
            return "D";
        }
        
        static private function initE():Boolean
        {
            trace("Init E2:", D, E, F);
            return true;
        }
    }
}

它输出以下内容：

Init D: null false 30
Init D2: null false 30
Init E2: undefinedD false 30
Init E: undefinedD false 30
Init E2: undefinedD false 30

Init A: 0 null 20 undefinedD
Init B2: 10 null 20 undefinedD
Init B: 10 null 20 undefinedD
Init B2: 10 null 20 undefinedD

Check ABC: 10 BundefinedB 20
Check DEF: undefinedD true 30

让我们理解结果：

1. 在执行应用程序代码的第一行之前，所有 static 常量 go。 在主文档 class 之前的非静态常量也是如此。 这一切都在意料之中。
2. 在相同的那些（即static 或非静态）中，首先初始化那些可以立即计算的，那些具有直接值或简单公式的。 实际上，它们甚至可以在编译时定义。
3. rest，在同一（静态或非静态）组中的那些，go，按照它们声明的确切顺序。
4. 我以为你可以在构造函数块中初始化常量，但事实证明你不能。 也许在AS2中是这样，我现在不记得了。
5. 在构造函数开始执行的那一刻，所有 class 成员常量都已经初始化。