在给定的列数中拆分 100% 宽度 随机宽度

Question

我想在给定数量的列中拆分 100%。 但列的宽度应该是随机的。 这是我的第一次尝试。 但它是 static 到 5 列。 有什么想法让它充满活力吗？

(defn create-columns []

  (let [col1 (int (random/number 14 26))
        col2 (int (random/number 14 26))
        col3 (int (random/number 14 26))
        col4 (int (random/number 14 26))
        col5 (- 100 (+ col1 col2 col3 col4))]

    [{:width col1, :left 0}
     {:width col2, :left (int col1)}
     {:width col3, :left (+ col1 col2)}
     {:width col4, :left (+ col1 col2 col3)}
     {:width col5, :left (+ col1 col2 col3 col4)}]))

结果应该像

[{:width 23, :left 0} {:width 24, :left 23} {:width 23, :left 47} {:width 14, :left 70} {:width 16, :left 84}]

和想法？

Answer 1

这是一个表示为惰性序列操作的算法：

1. 生成分隔列的随机位置，包括左右边界。
2. 对所有位置进行排序
3. 形成对每一个 position 和下一个
4. Map 对映射到:left和:width 。

这是执行此操作的代码。

(defn random-cols [total col-count]
  (->> #(rand-int (inc total))
       (repeatedly (dec col-count))
       (into [0 total])
       sort
       (partition 2 1)
       (map (fn [[left right]] {:left left :width (- right left)}))))

(random-cols 100 3)
;; => ({:left 0, :width 21} {:left 21, :width 24} {:left 45, :width 55})

这可以生成宽度小至 0 的列，但是将列限制为某个最小宽度可能是您可能想要做的事情，尽管问题没有说明这一点：

(defn random-cols-constrained [total col-count min-width]
  (let [widths (map #(+ min-width (:width %))
                    (random-cols (- total (* col-count min-width))
                                 col-count))]
    (map (fn [w l] {:width w :left l})
         widths
         (reductions + 0 widths))))