CMake 交叉编译 Windows 到 Windows

Question

有没有人尝试过在 cmake 中将 Windows 交叉编译为 Windows ？

我有一个异国情调的场景。 我正在参与一个使用 cmake 构建的开源项目。 该项目有几个平台端口。 例如。 Windows、Linux等。每个平台都有自己的cmake下标，有些还有单独的工具链脚本。

我想添加另一个端口/平台：Win32 FreeRTOS。 win32 FreeRTOS 本身就是一种好奇心。 最好的教育。 因此它不应该污染现有的 Windows 端口。 因此，我创建了一个名为 win32freertos.cmake 的新平台脚本。 在其中编译了一组不同的文件和库。 我创建了一个新的工具链脚本，就像交叉编译时所做的那样：

我认为它不应该包含太多内容。

include_guard()

# The name of the target operating system
set(CMAKE_SYSTEM_NAME win32freertos)

然后它使用 Microsoft Visual Studio CMake 构建：（与其他 Windows 端口相同。）

cmake -B build.win32freertos -DCMAKE_TOOLCHAIN_FILE=cmake/tools/toolchain/win32freertos.cmake

这在某种程度上有效。 缺少一些编译器参数。 这可以通过以下方式解决：

add_definitions(-DWIN32 -D_WINDOWS)
add_compile_options(/Zi /Od /Ob0 /WX /RTC1 /GR /MDd /EHsc)
add_link_options(/DEBUG /INCREMENTAL)

在这一点上，至少从表面上看，一切似乎都还不错。 唯一的问题是，编译后的 output 被命名为“.a”（用于库）和“”用于 exe 文件。 （Unix 风格的 output 文件。）这使得单元测试失败。 （而且这很糟糕。）通常这将通过以下方式解决：

set(CMAKE_EXECUTABLE_SUFFIX ".exe")

不幸的是，这不起作用。 （？？？）似乎没有任何效果。 似乎在创建新平台时，MSVC (Visual Studio) / CMake 中缺少一些重要的初始化。 所以，相反，我想出了这个：

set(CMAKE_CXX_COMPILER_VERSION "19.28") #Visual Studio 16 2019
include("${CMAKE_ROOT}/Modules/Platform/Windows-MSVC-CXX.cmake")
include("${CMAKE_ROOT}/Modules/Platform/Windows.cmake")

这行得通。 但这是一个非常脆弱的解决方案。 例如。 我硬编码了 Visual Studio 编译器版本（实际上是 MSC_VER。）我硬编码了一些随机的 Visual Studio cmake 脚本路径，下次升级 VS。 这可能会失败。 否则在使用较旧的 VS 时会失败，而且写这样的东西很糟糕。 在构建脚本中。

顺便说一句，我还没有找到从系统中检索 MSC_VER 的任何方法。 有一些相关的值，可以提取：

CMAKE_GENERATOR Visual Studio 16 2019
VSCMD_VER=16.8.4
VCToolsVersion=14.28.29333

但它们无法转换为我发现的 MSC_VER。 另外，忘记大多数 cmake 变量，你认为你知道。 在这一点上，它们还没有设置。 （上面的 Windows CMake 脚本设置了很多。）

有人有什么好的建议吗？ 在 CMake 中构建 Windows 应用程序时，有没有人尝试过创建备用工具链脚本？

Answer 1

避免使用目录命令add_definitions 、 add_compile_options 、 add_link_options等。而是将它们添加到标准_INIT变量中的工具链文件中。

也可以使用其特定于语言的变体来覆盖后缀：

set(CMAKE_SYSTEM_NAME win32freertos)

set(CMAKE_CXX_FLAGS_INIT "-DWIN32 -D_WINDOWS /Zi /Od /Ob0 /WX /RTC1 /GR /MDd /EHsc")
set(CMAKE_C_FLAGS_INIT "-DWIN32 -D_WINDOWS /Zi /Od /Ob0 /WX /RTC1 /GR /MDd /EHsc")
set(CMAKE_EXE_LINKER_FLAGS_INIT "/DEBUG /INCREMENTAL")
set(CMAKE_SHARED_LINKER_FLAGS_INIT "/DEBUG /INCREMENTAL")
set(CMAKE_STATIC_LINKER_FLAGS_INIT "/DEBUG /INCREMENTAL")
set(CMAKE_MODULE_LINKER_FLAGS_INIT "/DEBUG /INCREMENTAL")

set(CMAKE_EXECUTABLE_SUFFIX_CXX ".exe")
set(CMAKE_EXECUTABLE_SUFFIX_C ".exe")

set(CMAKE_SHARED_LIBRARY_SUFFIX_CXX ".dll")
set(CMAKE_SHARED_LIBRARY_SUFFIX_C ".dll")

set(CMAKE_SHARED_MODULE_SUFFIX_CXX ".dll")
set(CMAKE_SHARED_MODULE_SUFFIX_C ".dll")

set(CMAKE_STATIC_LIBRARY_SUFFIX_CXX ".lib")
set(CMAKE_STATIC_LIBRARY_SUFFIX_C ".lib")

set(CMAKE_IMPORT_LIBRARY_SUFFIX_CXX ".lib")
set(CMAKE_IMPORT_LIBRARY_SUFFIX_C ".lib")

如果没有 MVE，很难知道这是否可行。

Answer 2

有了上面的提示，我创建了这个工具链文件。 到目前为止，它看起来很有希望。

# The name of the target operating system
set(CMAKE_SYSTEM_NAME win32freertos)

set(CMAKE_C_FLAGS_DEBUG_INIT "/MDd /Zi /Ob0 /Od /RTC1")
set(CMAKE_C_FLAGS_INIT "/DWIN32 /D_WINDOWS /W3")
set(CMAKE_C_FLAGS_MINSIZEREL_INIT "/MD /O1 /Ob1 /DNDEBUG")
set(CMAKE_C_FLAGS_RELEASE_INIT "/MD /O2 /Ob2 /DNDEBUG")
set(CMAKE_C_FLAGS_RELWITHDEBINFO_INIT "/MD /Zi /O2 /Ob1 /DNDEBUG")

set(CMAKE_CXX_FLAGS_DEBUG_INIT "/MDd /Zi /Ob0 /Od /RTC1")
set(CMAKE_CXX_FLAGS_INIT "/DWIN32 /D_WINDOWS /W3 /GR /EHsc")
set(CMAKE_CXX_FLAGS_MINSIZEREL_INIT "/MD /O1 /Ob1 /DNDEBUG")
set(CMAKE_CXX_FLAGS_RELEASE_INIT "/MD /O2 /Ob2 /DNDEBUG")
set(CMAKE_CXX_FLAGS_RELWITHDEBINFO_INIT "/MD /Zi /O2 /Ob1 /DNDEBUG")

set(CMAKE_EXE_LINKER_FLAGS_DEBUG_INIT "/debug /INCREMENTAL")
set(CMAKE_EXE_LINKER_FLAGS_INIT "/machine:x64")
set(CMAKE_EXE_LINKER_FLAGS_MINSIZEREL_INIT "/INCREMENTAL:NO")
set(CMAKE_EXE_LINKER_FLAGS_RELEASE_INIT "/INCREMENTAL:NO")
set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO_INIT "/debug /INCREMENTAL")

set(CMAKE_SHARED_LINKER_FLAGS_DEBUG_INIT "/debug /INCREMENTAL")
set(CMAKE_SHARED_LINKER_FLAGS_INIT "/machine:x64")
set(CMAKE_SHARED_LINKER_FLAGS_MINSIZEREL_INIT "/INCREMENTAL:NO")
set(CMAKE_SHARED_LINKER_FLAGS_RELEASE_INIT "/INCREMENTAL:NO")
set(CMAKE_SHARED_LINKER_FLAGS_RELWITHDEBINFO_INIT "/debug /INCREMENTAL")

set(CMAKE_STATIC_LINKER_FLAGS_INIT "/machine:x64")

set(CMAKE_EXECUTABLE_SUFFIX_CXX ".exe")
set(CMAKE_EXECUTABLE_SUFFIX_C ".exe")
set(CMAKE_SHARED_LIBRARY_SUFFIX_CXX ".dll")
set(CMAKE_SHARED_LIBRARY_SUFFIX_C ".dll")
set(CMAKE_SHARED_MODULE_SUFFIX_CXX ".dll")
set(CMAKE_SHARED_MODULE_SUFFIX_C ".dll")
set(CMAKE_STATIC_LIBRARY_SUFFIX_CXX ".lib")
set(CMAKE_STATIC_LIBRARY_SUFFIX_C ".lib")
set(CMAKE_IMPORT_LIBRARY_SUFFIX_CXX ".lib")
set(CMAKE_IMPORT_LIBRARY_SUFFIX_C ".lib")