如何防止 neo4j MERGE 创建重复关系？

Question

如果它们不存在，我正在尝试创建节点和关系。 我不知道数据库中是否存在任何东西。

这是我的初始查询：

MERGE (t:type { name: 'aaa'})
MERGE (m:model { name: 'bbb'})
MERGE (r:region {name: 'ccc'})
MERGE (p:param {name: 'ddd'})
MERGE (i:init {value: 123})
MERGE (u:forecast {url: 'http://something.png'})
MERGE (t)-[:HAS]-(m)-[:HAS]-(r)-[:HAS]-(p)-[:HAS]-(i)-[:HAS]-(u)

这会正确生成如下图：

然后我再次运行此查询，但这次我将“模型”object 的名称更改为“bbc”（而不是“bbb”）：

MERGE (t:type { name: 'aaa'})
MERGE (m:model { name: 'bbc'})
MERGE (r:region {name: 'ccc'})
MERGE (p:param {name: 'ddd'})
MERGE (i:init {value: 123})
MERGE (u:forecast {url: 'http://something.png'})
MERGE (t)-[:HAS]-(m)-[:HAS]-(r)-[:HAS]-(p)-[:HAS]-(i)-[:HAS]-(u)

但是，现在我的图表如下所示：

除了三个重复的关系之外，一切看起来都是正确的。 我意识到如果MATCH不存在，它将创建整个路径。 但是，必须有某种方法来避免创建重复的关系。

我将不胜感激被指出正确的方向！

Answer 1

MERGE语句检查整个模式是否已经存在。 因此，如果有一个节点不同，则将整个模式确定为不存在并创建所有关系。

解决方案是将这个MERGE语句拆分为多个，即每个关系一个MERGE ：

MERGE (t)-[:HAS]-(m)-[:HAS]-(r)-[:HAS]-(p)-[:HAS]-(i)-[:HAS]-(u)

变成

MERGE (t)-[:HAS]-(m)
MERGE (m)-[:HAS]-(r)
MERGE (r)-[:HAS]-(p)
MERGE (p)-[:HAS]-(i)
MERGE (i)-[:HAS]-(u)