如何在日期之间创建变量

Question

我正在努力创建间隔日期的财政年度变量。 我想要变量，例如 1819（2018/19 财年）等。

data mydata;
    set mydata;
    FinYear = 9999.;
    if '01JUL2018'd <= ConductedDate <= '30JUN2019'd then FinYear=1819;
run;

有什么我做错了吗？ 它不工作。

Answer 1

不确定您做错了什么，但是，无论如何，这是一种更好的方法。 请注意，这假设您的输入变量是数字日期变量，而不是字符变量 - 检查是否是字符变量。 您需要将其输入到数字日期变量中。

首先我们制作一些假数据——你不应该需要这一步：

data have;
  format datevar date9.;
  do datevar = '02JAN2017'd to '01FEB2021'd by 20;
    output;
  end;
run;

现在我们使用INTNX （时间间隔增量函数）和 YEAR.7 间隔（YEAR，但移动 7 - 在本例中为 7 个月 - 所以它是每个 7 月 1 日）并从中提取YEAR() 。 最后，我们使用模（余数）function 进行一些数学运算以获取您的确切值（从该日期的年份部分），获取最后 2 位数字并将其加一。

data want;
  set have;
  fy_start = year(intnx('year.7',datevar,0));
  finyear = cats(mod(fy_start,100),mod(fy_start+1,100));
run;
  

我会注意到我并不特别喜欢这样做——有更好的方法，特别是使用格式，来显示日期值在实际生成原始数据值时是哪个财政年度。

proc format;
  value finyr
  '01JUL2016'd - '30JUN2017'd = '1617'
  '01JUL2017'd - '30JUN2018'd = '1718'
  '01JUL2018'd - '30JUN2019'd = '1819'
  '01JUL2019'd - '30JUN2020'd = '1920'
  '01JUL2020'd - '30JUN2021'd = '2021'
  '01JUL2021'd - '30JUN2022'd = '2122'
  ;
quit;

data want;
  set have;
  format datevar finyr.;
run;

如果你真的需要它的值，你当然可以使用 PUT ( newval = put(datevar finyr.);)

可以使用 CNTLIN 数据集以编程方式而不是像上面那样手动制作格式，以避免每年都必须更新它。

Answer 2

您可以尝试将第 4 行代码修改为：

data mydata;
set mydata;
FinYear = 9999.;
if '01JUL2018'd <= ConductedDate and ConductedDate <= '30JUN2019'd then FinYear=1819;
run;

谢谢