变量中的 awk 运算符

Question

我有 2 个文件

cat file1.txt
lspol > 8296
....
cat file2.txt
lspol 8297
...

如果 file2.txt 中第 1 列的数字大于 file1.txt 中第 1 列的数字，我正在尝试获取 output

下面的命令效果很好

# if column 1 of file1.txt is equal to column 1 of file2.txt and column 3 of file1.txt is greater than column 2 in file2.txt
awk '
   {
       getline buf <f2;
       split( buf, a, " " );
       if( $1 == a[1]  && $3+0 > a[2]+0 )
           printf( "%s\n", buf );
   }
' f2="file2.txt" file1.txt

我试图从 file1.txt 的第二列中拉出运算符，但没有运气。 我尝试了很多方法，这里是其中之一

awk '
   {
       getline buf <f2;
       split( buf, a, " " );
       if( $1 == a[1]  && $3+0 $2 a[2]+0 )
           printf( "%s\n", buf );
   }
' f2="file2.txt" file1.txt

Answer 1

使用未经验证的输入总是有风险的，但我认为这可能是你想要做的：

$ cat tst.awk
NR==FNR {
    ops[$1] = $2
    vals[$1] = $3
    next
}
{ comparison = sprintf("%d %s %d", $2, ops[$1], vals[$1]) }
system("awk \047BEGIN{exit} END{exit (" comparison ")}\047")

$ awk -f tst.awk file1 file2
lspol 8297

每行末尾的数值已经是安全的，因为如果它们还不是数字，它们会专门转换为数字，您可以通过以下方式使操作员安全：

$ cat tst.awk
NR==FNR {
    if ( $2 ~ /^[!<>=~]{1,2}$/ ) {
        ops[$1]  = $2
        vals[$1] = $3
    }
    else {
        print "Bad operator:", $2 | "cat>&2"
        exit 1
    }
    next
}
{ comparison = sprintf("%d %s %d", $2, ops[$1], vals[$1]) }
system("awk \047BEGIN{exit} END{exit (" comparison ")}\047")

或其他一些这样的正则表达式，用于您想要支持的任何比较运算符。

上述作弊因为它没有在 1 awk 命令中评估运算符，而是使用 awk 调用 awk 通过测试的表达式来评估您想要的表达式。 鉴于此，它将比在 1 个 awk 命令中硬编码比较慢几个数量级。

有关类似脚本，另请参阅https://stackoverflow.com/a/54161251/1745001 。

如果这不是您想要做的，那么编辑您的问题以阐明您的要求并提供更具代表性的示例输入/输出。

Answer 2

你可以建造这样的东西......

$ awk 'NR==FNR{cond[$1]=$2; v[$1]=$3; next}
              {switch(cond[$1])  {
                 case "<": if($2<v[$1]) print; break;
                 case ">": if($2>v[$1]) print; break;
                 case "=": if($2==v[$1]) print; break;
                 default: print "unknown op or missing " $1; break;
              }}' file1 file2

lspol 8297