在 gnuplot 中向 label 添加彩色线？

Question

我想知道是否可以在 gnuplot 中的 label 命令中添加一条彩色线？ 也就是说，假设我想在 label 命令中的一些文本之后添加一条红线：

set label "some text here which is then followed by a red horizontal line -----" at 100,200 front

基本上，我想在 label 命令中模仿 gnuplot 中密钥的通常表示。 我已经有一个密钥，并且在同一个 plot 环境中不允许使用另一个密钥，因此我想通过 label 命令手动构造第二个密钥。

提前致谢。

Answer 1

您可以通过绘制全部无效的数据（NaN，而不是数字）来获得第二个键。 例如，

cat >data <<\!
 17  15
 18  5 
 19  10
 21  7   
!
gnuplot -persist <<\!
plot "data" u 1:2 with lines title "plot1", \
 "" u (NaN):(NaN) with lines title "plot2"
!

Answer 2

我会按照以下方式进行。 查看help arrow的详细信息和help label 。

编辑：使用单独的行和标签当然是更多的代码，但你有充分的灵活性。 我想这取决于你到底想做什么。

代码：

### labels with lines
reset session

set size ratio -1

set arrow 1 from 4,0 to 7,0 lc "red" lw 2 nohead
set label 1 at 4,0 "Some text" right offset -1,0

set arrow 2 from 2,-2 to 5,-2 lc "red" lw 2 dt 3 nohead
set label 2 at 5,-2 "Some text" left offset 1,0

set arrow 3 from -6,5 to -2,5 lc "red" lw 2 dt 1 nohead
set label 3 at -4,5 "Some text" center offset 0,-1

set arrow 4 from -6,-2 length 5.5 angle 45 lc "red" lw 2 dt 3 nohead
set label 4 at -6,-2  "Some text" font ",14" right rotate by 45 offset -1,0

plot x w l lc "blue"
### end of code

结果：

Answer 3

您可以使用带有关键字keyentry而不是文件名的 plot 子句来为密钥生成额外的标题和行/点/填充示例。 您还可以使用at <x-pos>,<y-pos>处的关键字将这个额外的标题放置在页面的其他位置。

来自在线演示集的示例：

• 自定义密钥生成
• 额外的关键条目

这里的快速示例：

set xrange [0:20]
plot x**2, x**3, \
     keyentry with lines dt '-' lc "red" title "Extra title" at graph 0.25, graph 0.75