宏在 PC 上运行但不在 MacOS 上运行：下标超出范围错误

Question

我可以让这段代码在 PC 上运行，但不能在 Mac 上运行。 该代码允许您将 select 文本文件转换为工作表，并将 append 转换为您当前的工作簿。

Set wkbTemp = Workbooks.Open(FileName:=FilesToOpen(x))

上述代码行将程序发送到错误处理程序并导致下标超出范围错误。

在下面的链接中是一张本地人 Window 的图片，它显示了我希望抓取的文件的路径名。 https://imgur.com/a/wPzH5VB

Sub CombineTextFiles()

Dim FilesToOpen
Dim x As Integer
Dim wkbAll As Workbook
Dim wkbTemp As Workbook
Dim sDelimiter As String
Dim answer As Integer

On Error GoTo ErrHandler
Application.ScreenUpdating = False

answer = MsgBox("Before moving forward, all other workbooks must be closed" _
& vbCrLf & "Do you wish to continue?", vbYesNo + vbQuestion)

If answer = vbYes Then 'do nothing
Else: Exit Sub
End If

sDelimiter = ","

#If Mac Then
FilesToOpen = Select_File_Or_Files_Mac()
#Else
FilesToOpen = Application.GetOpenFilename(fileFilter:="Text Files (*.txt), *.txt", _
  MultiSelect:=True, Title:="Select the CDR Text Files to Open")
#End If


If TypeName(FilesToOpen) = "Boolean" Then
    MsgBox "No Files were selected"
    GoTo ExitHandler
End If

x = 1
Set wkbTemp = Workbooks.Open(FileName:=FilesToOpen(x))
wkbTemp.Sheets(1).Copy
Set wkbAll = ActiveWorkbook
wkbTemp.Close (False)
wkbAll.Worksheets(x).Columns("A:A").TextToColumns _
  Destination:=Range("A1"), DataType:=xlDelimited, _
  TextQualifier:=xlDoubleQuote, _
  ConsecutiveDelimiter:=False, _
  Tab:=False, Semicolon:=False, _
  Comma:=False, Space:=False, _
  Other:=True, OtherChar:=","
x = x + 1

While x <= UBound(FilesToOpen)
    Set wkbTemp = Workbooks.Open(FileName:=FilesToOpen(x))
    With wkbAll
        wkbTemp.Sheets(1).Move After:=.Sheets(.Sheets.Count)
        .Worksheets(x).Columns("A:A").TextToColumns _
          Destination:=Range("A1"), DataType:=xlDelimited, _
          TextQualifier:=xlDoubleQuote, _
          ConsecutiveDelimiter:=False, _
          Tab:=False, Semicolon:=False, _
          Comma:=False, Space:=False, _
          Other:=True, OtherChar:=sDelimiter
    End With
    x = x + 1
Wend

wkbAll.Sheets.Copy After:=Workbooks(2).Sheets(Workbooks(2).Worksheets.Count)
wkbAll.Close False
    
ExitHandler:
    Application.ScreenUpdating = True
    Set wkbAll = Nothing
    Set wkbTemp = Nothing
    Exit Sub

ErrHandler:
    MsgBox Err.Description
    Resume ExitHandler


End Sub

Function Select_File_Or_Files_Mac() As String()
Dim MyPath As String
Dim MyScript As String
Dim MyFiles As String
Dim MySplit As Variant
Dim N As Long
Dim FName As String
Dim mybook As Workbook

On Error Resume Next
MyPath = MacScript("return (path to documents folder) as String")
'Or use MyPath = "Macintosh HD:Users:Ron:Desktop:TestFolder:"

' In the following statement, change true to false in the line "multiple
' selections allowed true" if you do not want to be able to select more
' than one file. Additionally, if you want to filter for multiple files, change
' {""com.microsoft.Excel.xls""} to
' {""com.microsoft.excel.xls"",""public.comma-separated-values-text""}
' if you want to filter on xls and csv files, for example.
MyScript = _
"set applescript's text item delimiters to "","" " & vbNewLine & _
           "set theFiles to (choose file of type " & _
         " {""com.microsoft.excel.xls"",""public.comma-separated-values-text"", ""public.text""} " & _
           "with prompt ""Please select a file or files"" default location alias """ & _
           MyPath & """ multiple selections allowed true) as string" & vbNewLine & _
           "set applescript's text item delimiters to """" " & vbNewLine & _
           "return theFiles"

MyFiles = MacScript(MyScript)
Dim returnList() As String
On Error GoTo 0

If MyFiles <> "" Then
    With Application
        .ScreenUpdating = False
        .EnableEvents = False
    End With

    'MsgBox MyFiles
    MySplit = Split(MyFiles, ",")
    ReDim returnList(LBound(MySplit) To UBound(MySplit))
    For N = LBound(MySplit) To UBound(MySplit)

        returnList(N) = MySplit(N)

    Next N
    With Application
        .ScreenUpdating = True
        .EnableEvents = True
    End With
    Select_File_Or_Files_Mac = returnList
Else
    ReDim returnList(0 To 0)
    returnList(0) = "False"
    Select_File_Or_Files_Mac = returnList
End If
End Function

Answer 1

Application.GetOpenFilename和Select_File_Or_Files_Mac都返回一个包含一个或多个文件名的数组，但第一个数组是从 1 开始的，而您的 Mac 版本是从0 开始的。

您的计数器x从1 开始，因此它已经超出了只有一个文件的“mac”数组的范围：即FilesToOpen(0)

您可以修改 Mac 代码以返回从 1 开始的数组。

修改这部分：

MySplit = Split(MyFiles, ",")

ReDim returnList(1 to To UBound(MySplit)+1) 'one-based not zero-based...

For N = LBound(MySplit) To UBound(MySplit)
    returnList(N + 1) = MySplit(N)
Next N

...这部分：

ReDim returnList(1 To 1)
returnList(1) = "False"