为什么我的查询在程序 (PL/SQL) 中没有返回任何记录，但在 SQL 中手动运行时会返回？

Question

大家好，感谢您抽出宝贵时间帮助我。

我有以下查询：

SELECT   owner, object_name
FROM     all_objects
WHERE    owner IN ('EDI')
ORDER BY object_type, object_name;

正如您在屏幕截图中看到的，它返回一些值。

当我从程序内部调用查询时，它没有返回任何值（参见第二个屏幕截图）。

说明这一点的测试代码是：

CREATE OR REPLACE PROCEDURE my_test
AS
BEGIN
    DBMS_OUTPUT.put_line('Pre-Loop');

    FOR indx IN (SELECT   owner, object_name
                 FROM     all_objects
                 WHERE    owner IN ('EDI')
                 ORDER BY object_type, object_name)
    LOOP
        DBMS_OUTPUT.put_line('Object: ' || indx.owner || '.' || indx.object_name);
    END LOOP;

    DBMS_OUTPUT.put_line('Post-Loop');
END;
/

BEGIN
    my_test();
END;
/

EDI 模式是全新的，所以我怀疑这是一个授权/特权问题，但我似乎无法找到我可能缺少的东西以使其正常工作。 我尝试以 EDI 用户和 SYS 的身份运行它。

得到答案后编辑：

我在评论中提到要找到该问题的官方答案的替代方案，并希望确保将其分享给稍后阅读此内容的任何人，以便他们可以权衡相同的决定。

向预期运行代码的用户应用EXECUTE ANY PROCEDURE或SELECT ANY TABLE之类的授权将起作用，但我确信有理由不提供如此广泛的授权。

Answer 1

您的存储过程是定义者权限存储过程。 这意味着它无法访问通过角色授予的权限，只有那些直接授予过程所有者的权限。 另一方面，即席 SQL 除了用户的直接授权外，还以当前 session 启用的任何角色的权限运行。 最有可能的是，该过程的所有者可以通过角色而不是通过直接授权访问相关表。

您可以通过运行来测试它

set role none;

然后运行临时 SQL 语句。 如果我的赌注是正确的，那么临时 SQL 现在将返回 0 行，因为您已禁用 session 的所有角色。

根据您要对该过程执行的操作，您可以通过将其转换为调用者权限存储过程来解决问题。

CREATE OR REPLACE PROCEDURE my_test
  AUTHID CURRENT_USER
AS

这将导致过程以调用者的 session 的权限（包括通过角色授予的权限）而不是定义者的权限运行。 假设您要调用该过程的所有用户都可以访问EDI表，这就足够了。

Answer 2

这就是你现在所拥有的——根本没有结果：

SQL> CREATE OR REPLACE PROCEDURE my_test
  2  AS
  3  BEGIN
  4      DBMS_OUTPUT.put_line('Pre-Loop');
  5
  6      FOR indx IN (SELECT   owner, object_name
  7                   FROM     all_objects
  8                   WHERE    owner IN ('SCOTT')
  9                     AND    rownum < 5               -- you don't have that
 10                   ORDER BY object_type, object_name)
 11      LOOP
 12          DBMS_OUTPUT.put_line('Object: ' || indx.owner || '.' || indx.object_name);
 13      END LOOP;
 14
 15      DBMS_OUTPUT.put_line('Post-Loop');
 16  END;
 17  /

Procedure created.

SQL> BEGIN
  2      my_test();
  3  END;
  4  /

PL/SQL procedure successfully completed.

但是，如果您启用 serveroutput ，就在这里！

SQL> set serveroutput on                       --> this!
SQL>
SQL> BEGIN
  2      my_test();
  3  END;
  4  /
Pre-Loop
Object: SCOTT.BONUS
Object: SCOTT.DEPT
Object: SCOTT.EMP
Object: SCOTT.SALGRADE
Post-Loop

PL/SQL procedure successfully completed.

SQL>