将“GroupItems”的元素转换为“Shape”

Question

我在文档中有一个分组形状：

Dim doc As Word.Document
Set doc = Documents("dlr-overview.docx")
Dim firstShape As Word.Shape
Set firstShape = doc.Shapes(1)

firstShape上的AutoShapeType返回-2或msoShapeMixed ； 并且firstShape.GroupItems.Count返回25 ：

Debug.Print firstShape.AutoShapeType
Debug.Print firstShape.GroupItems.Count

我可以迭代firstShape.GroupItems中的形状，而无需转换为Shape 。 TypeName为每个元素返回"Shape" ， AutoShapeType属性返回5或msoShapeRoundedRectangle ：

Dim x As Variant
For Each x In firstShape.GroupItems
    Debug.Print TypeName(x)
    Debug.Print x.AutoShapeType
Next

但是当我尝试将每个元素强制转换为Shape时，我在For Each的第一次迭代中得到Type mismatch ：

Dim subshape As Shape
For Each subshape In firstShape.GroupItems
    Debug.Print subshape.Left
Next

如何从分组形状中提取有关单个形状的信息？

Answer 1

似乎不可能在从Shape.GroupItems返回的GroupShapes object 上使用Shape变量进行枚举。 以下也是迭代中的错误：

Dim shapes As GroupShapes
Set shapes = firstShape.GroupItems
Dim shp As Shape
For Each shp In shapes
    Debug.Print shp.Name
Next

显然，返回的元素不是Word.Shape对象，即使TypeName function 返回此类对象的"Shape" 。

但是，如果我通过GroupShapes集合的Item属性或默认属性访问元素，它们将作为Word.Shape对象返回，并且可以转换为Word.Shape ：

Dim i As Integer
For i = 1 To firstShape.GroupItems.Count
    Dim shp As Shape
    Set shp = firstShape.GroupItems(i)
    Debug.Print shp.Name
Next