使用查找 function 时，如何将 append 转换为 VBA 中的 xlValues？

Question

我想做这样的事情：

inputSheet.UsedRange.Find(What:=Right("00000" & t.minRowCode, 5), LookIn:=Right("00000" & xlValues, 5))

这是可能的还是我做错了什么？

Answer 1

minRowCode 可以具有类似 ("010","10","0010") 的值，excel 工作表包含一个表格，其中包含行代码和列代码的标签。 这些标签可以是 ("010","10","0010")。 我想找到行代码 label 即使它前面可能有 2 个或 3 个零或没有。 – Olteanu Radu 1 小时前

这是你正在尝试的吗？

Option Explicit

Sub Sample()
    Dim ws As Worksheet
    Dim aCell As Range
    Dim bCell As Range
    Dim SearchString As String
    Dim FoundAt As String
    
    '~~> Change this to the relevant sheet
    Set ws = Sheet1
    
    '~~> This is your search string
    SearchString = "10"
    
    With ws
        Set aCell = .UsedRange.Find(What:=SearchString, LookIn:=xlValues, _
            LookAt:=xlPart, SearchOrder:=xlByRows, SearchDirection:=xlNext, _
            MatchCase:=False, SearchFormat:=False)
    
        If Not aCell Is Nothing Then
            Set bCell = aCell
            
            '~~> Do a Value comparision rather than adding leading and trailing 0's
            If Val(aCell.Value2) = Val(SearchString) Then
                FoundAt = aCell.Address
            End If
            
            '~~> Find next Entry
            Do
                Set aCell = .UsedRange.FindNext(After:=aCell)
    
                If Not aCell Is Nothing Then
                    If aCell.Address = bCell.Address Then Exit Do
                    If Val(aCell.Value2) = Val(SearchString) Then
                        FoundAt = FoundAt & ", " & aCell.Address
                    End If
                Else
                    Exit Do
                End If
            Loop
        Else
            MsgBox SearchString & " not Found"
        End If
    End With
    
    If FoundAt <> "" Then _
    MsgBox "Found " & SearchString & " in cells " & FoundAt
End Sub

注意：如果您打算使用类似SearchString = "0010"的内容，请将What:=SearchString更改为What:=Val(SearchString)

Answer 2

请尝试这种方式：

Sub testFindPart()
 Dim sh As Worksheet, C As Range, firstAddress As String
 
 Set sh = ActiveSheet

 Set C = sh.UsedRange.Find(What:="10", LookIn:=xlValues, lookat:=xlPart)

 firstAddress = C.Address
 If Not C Is Nothing Then
    Do
        Set C = sh.UsedRange.FindNext(C)
        Debug.Print C.Address, C.row
    Loop While C.Address <> firstAddress
 End If
End Sub

但是，就像我在评论中所说的那样，它还会找到一个字符串“23451078”......

而且，如果您需要一些列标题，您可以将范围定义为讨论中的行。