julia 抛出：“new{…}”中指定的类型参数太少

Question

我想制作一个类似于下面的struct C的结构，但是C.a和C.b属于同一类型：

struct C
    a::Array
    b::Array
    
    function C(a, b)
        length(a) == length(b) || throw(DimensionMismatch())
        new(a, b)
    end
end

我认为通过执行以下操作来实现这将是微不足道的：

struct D{T<:Int}
    a::Array{T}
    b::Array{T}
    
    function D(a, b)
        length(a) == length(b) || throw(DimensionMismatch())
        new(a, b)
    end
end

但它会抛出一个错误：

# syntax: too few type parameters specified in "new{...}" around

我在julia discourse上找到了解决方案的开头。

struct E{T<:Int}
    a::Array{T}
    b::Array{T}
    
    function E(a::Array{S}, b::Array{S}) where S<:Int
        length(a) == length(b) || throw(DimensionMismatch())
        new{S}(a, b)
    end
end

错误消失了。 但由于某种原因，它不适用于所有Int

v = Array{Int64}([1,2])
w = Array{Int32}([1,2])

E(v, v)
# E{Int64}(Int64[1, 2], Int64[1, 2])

E(v, v)
# MethodError: no method matching Main.workspace321.E(::Array{Int32,1}, ::Array{Int32,1})

有人知道这里发生了什么吗？

Answer 1

我发现问题Int是Int64的别名（我想，我在文档中找不到它。）。 任何状况之下：

julia> Int32 <: Integer
true

julia> Int32 <: Int
false

julia> Int64 <: Int
true

julia> Int64 == Int 
true

help?> Int
search: Int Int8 Int64 Int32 Int16 Int128 Integer ...

  Int64 <: Signed

  64-bit signed integer type.

所以这有效：

struct E{T<:Integer}
    a::Array{T}
    b::Array{T}
    function E(a::Array{S}, b::Array{S}) where S<: Integer
        length(a) == length(b) || throw(DimensionMismatch())
        new{S}(a, b)
    end
end