查找数组的名称

Question

我有这个代码：

Array1 = Array("apple", "pear")
Array2 = Array("Dog", "Cat")

All_Arrays = Array(Array1, Array2) 
For each item in All_Arrays
    Debug.print item
Next item

我想将其更改为打印变量名Array1和Array2 。 这可能吗？

Answer 1

我会使用Dictionary ，用标识符名称键入：

Dim Array1 As Variant
Array1 = Array("apple", "pear")

Dim Array2 As Variant
Array2 = Array("Dog", "Cat")

With New Scripting.Dictionary

    .Add "Array1", Array1
    .Add "Array2", Array2

    Dim names As Variant
    names = .Keys

    Dim outer As Long
    For outer = LBound(names) To UBound(names)

        Dim k As String
        k = names(outer)

        Debug.Print k & ":"

        Dim inner As Long
        For inner = LBound(.Item(k)) To UBound(.Item(k))
            Debug.Print vbTab & .Item(k)(inner)
        Next
    Next

End With

Output：

Array1:
    apple
    pear
Array2:
    Dog
    Cat

Answer 2

是的，一直使用嵌套的 arrays ......

For iArr = 0 to ubound(All_Arrays)
    subArr = All_Arrays(iArr)   '0 will be Array1, 1 will be Array2
    'Then do whatever you want with subArr
next iArr

edit1：哦，也许你想要实际的变量名？ “Array_1”和“Array_2”作为字符串？ 如果不明确交还名称字符串，这是不可能的（据我所知）。 IE

All_Arrays_Names = Array("Array1", "Array2")

edit2：也许有可能，但肯定不是微不足道的： 打印变量的名称

Answer 3

Arrays 又名锯齿状数组的数组

Option Explicit

Sub testJaggedArray()
    
    Dim Array1 As Variant: Array1 = Array("apple", "pear")
    Dim Array2 As Variant: Array2 = Array("Dog", "Cat")

    Dim All_Arrays As Variant: All_Arrays = Array(Array1, Array2)

    Dim i As Long
    Dim k As Long
    
    For i = LBound(All_Arrays) To UBound(All_Arrays)
        For k = LBound(All_Arrays(i)) To UBound(All_Arrays(i))
            Debug.Print All_Arrays(i)(k)
        Next k
    Next i

End Sub

结果立即 Window ( CTRL + G )

apple
pear
Dog
Cat

要获得相同的结果，您也可以这样做：

For i = LBound(All_Arrays) To UBound(All_Arrays)
    Debug.Print Join(All_Arrays(i), vbLf)
Next i

Answer 4

使用锯齿状数组的非常基本的替代方案

数组不是 object 处理类似.Name属性的东西，但您可以构建一个 arrays 数组，也就是在其中定义您自己的名称的锯齿状数组。

这个想法是使用锯齿状数组的第一个元素（行）作为数组名称的容器，而只有后续元素包含相关的 arrays。 代替@MathieuGuindon 的有效字典方法，可以直接从锯齿状数组中读取名称（例如，通过此处的帮助 function Header() ）。

请注意，此示例中的数组名称称为序数（从 1 开始）。

下面的代码旨在演示一种替代方法，它给出了一个基本的起始想法，并且可以单独更改以满足更复杂的需求。 这可能包括错误处理、接受其他数组基础和函数以及开发其他 class 方法或属性。

Sub testJagged()
    Dim jagged: ReDim jagged(2)
    jagged(0) = Array("Array1", "Array2")
    jagged(1) = Array("Apple", "Pear")
    jagged(2) = Array("Dog", "Cat")
    
    Dim i As Long
    For i = LBound(jagged) + 1 To UBound(jagged)
        Debug.Print header(jagged, i) & ":"
        Debug.Print vbTab & Join(jagged(i), vbNewLine & vbTab)
    Next
    
    'how to refer to array names and selected elements
    Dim NamedElem
    For Each NamedElem In jagged(0)
        Debug.Print "all Elems of " & NamedElem & ": " & _
            Join(getNamedArray(jagged, NamedElem), ",")
        Debug.Print "1st Elem  of " & NamedElem & ": " & _
            getNamedArray(jagged, NamedElem)(0)
    Next


End Sub

帮助 function Header()

Function header(arr, ByVal OrdinalHeaderNum As Long)
'Note: assumes zero-based headers in jagged array
    header = arr(LBound(arr))(OrdinalHeaderNum - 1)
End Function

帮助 function getNamedArray()

Function getNamedArray(arr, ByVal ArrName As String)
    Dim num As Variant
    num = Application.Match(ArrName, arr(LBound(arr)), 0)
    If IsNumeric(num) Then getNamedArray = arr(num)
End Function

Output 在 VB 编辑器的立即 window 中：

Array1:
    Apple
    Pear
Array2:
    Dog
    Cat

all Elems of Array1: Apple Pear
1st Elem  of Array1: Apple
all Elems of Array2: Dog Cat
1st Elem  of Array2: Dog