XML 到 CSV 转换使用 XSLT

Question

我正在尝试将我的 xml 输入转换为 csv output 如下详细信息

输入文件：

<Customer>
   <item>
      <CustomerID>100000069</CustomerID>
      <CustomerGroup>EX</CustomerGroup>
      <CustomerName>Test Mehmet</CustomerName>
      <CustomerStreet>Street</CustomerStreet>
      <HouseNumber>123</HouseNumber>
      <CustomerCity>Ismaning</CustomerCity>
      <CustomerZip></CustomerZip>
      <CustomerCountry>DE</CustomerCountry>
   </item>
</Customer>

XSL：

<?xml version="1.0"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="text"/>
<xsl:variable name='newline'>
<xsl:text>
</xsl:text>
</xsl:variable>
<xsl:template match="/Customer">
<xsl:value-of select="concat('&quot;CustomerID&quot;;&quot;CustomerGroup&quot;;&quot;CustomerName&quot;;&quot;CustomerStreet&quot;;&quot;HouseNumber&quot;;&quot;CustomerCity&quot;;&quot;CustomerZIP&quot;;&quot;CustomerCountry&quot;',$newline)"/>
<xsl:for-each select="./item">
<xsl:value-of select="concat('&quot;',./CustomerID,'&quot;;&quot;',./CustomerGroup,'&quot;;&quot;',./CustomerName,'&quot;;&quot;',./CustomerStreet,'&quot;;&quot;',./HouseNumber,'&quot;;&quot;',./CustomerCity,'&quot;;&quot;',./CustomerZIP,'&quot;;&quot;',./CustomerCountry,'&quot;',$newline)"/>
</xsl:for-each>
</xsl:template>
</xsl:stylesheet>

我的原装 output：

"CustomerID";"CustomerGroup";"CustomerName";"CustomerStreet";"HouseNumber";"CustomerCity";"CustomerZIP";"CustomerCountry" "100000069";"EX";"Test Mehmet";"Street";"123 ";"伊斯马宁";"";"德"

预期 Output：

我需要将所有空值更改为“null”。 下面是我预期的 output。

"CustomerID";"CustomerGroup";"CustomerName";"CustomerStreet";"HouseNumber";"CustomerCity";"CustomerZIP";"CustomerCountry" "100000069";"EX";"Test Mehmet";"Street";"123 ";"伊斯曼宁";null;"DE"

请建议我的代码所需的额外更改，以便它将在“”出现的任何地方填充 null。

Answer 1

假设您仅限于 XSLT 1.0，我建议您这样做：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="text"/>

<xsl:template match="/Customer">
    <!-- header row -->
    <xsl:text>"CustomerID";"CustomerGroup";"CustomerName";"CustomerStreet";"HouseNumber";"CustomerCity";"CustomerZIP";"CustomerCountry"&#10;</xsl:text>
    <!-- data rows -->
    <xsl:for-each select="item">
        <xsl:call-template name="cell">
            <xsl:with-param name="data" select="CustomerID"/>
        </xsl:call-template>
        <xsl:text>;</xsl:text>
        <xsl:call-template name="cell">
            <xsl:with-param name="data" select="CustomerGroup"/>
        </xsl:call-template>
        <xsl:text>;</xsl:text>
        <xsl:call-template name="cell">
            <xsl:with-param name="data" select="CustomerName"/>
        </xsl:call-template>
        <xsl:text>;</xsl:text>
        <xsl:call-template name="cell">
            <xsl:with-param name="data" select="CustomerStreet"/>
        </xsl:call-template>
        <xsl:text>;</xsl:text>
        <xsl:call-template name="cell">
            <xsl:with-param name="data" select="HouseNumber"/>
        </xsl:call-template>
        <xsl:text>;</xsl:text>
        <xsl:call-template name="cell">
            <xsl:with-param name="data" select="CustomerCity"/>
        </xsl:call-template>
        <xsl:text>;</xsl:text>
        <xsl:call-template name="cell">
            <xsl:with-param name="data" select="CustomerZip"/>
        </xsl:call-template>
        <xsl:text>;</xsl:text>
        <xsl:call-template name="cell">
            <xsl:with-param name="data" select="CustomerCountry"/>
        </xsl:call-template>
        <xsl:text>&#10;</xsl:text>
    </xsl:for-each>
</xsl:template>

<xsl:template name="cell">
    <xsl:param name="data"/>
    <xsl:choose>
        <xsl:when test="string($data)">
            <xsl:text>"</xsl:text>
            <xsl:value-of select="$data"/>
            <xsl:text>"</xsl:text>
        </xsl:when>
        <xsl:otherwise>null</xsl:otherwise>
    </xsl:choose>
</xsl:template>

</xsl:stylesheet>

这有点冗长，但它避免了代码重复。

但是，如果您可以确定所有元素将始终以相同的顺序存在，即使有些可能是空的，您也可以将其缩短为：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="text"/>

<xsl:template match="/Customer">
    <!-- header row -->
    <xsl:text>"CustomerID";"CustomerGroup";"CustomerName";"CustomerStreet";"HouseNumber";"CustomerCity";"CustomerZIP";"CustomerCountry"&#10;</xsl:text>
    <!-- data rows -->
    <xsl:for-each select="item">
        <xsl:for-each select="*">
            <xsl:choose>
                <xsl:when test="string(.)">
                    <xsl:text>"</xsl:text>
                    <xsl:value-of select="."/>
                    <xsl:text>"</xsl:text>
                </xsl:when>
                <xsl:otherwise>null</xsl:otherwise>
            </xsl:choose>
            <xsl:if test="position()!=last()">;</xsl:if>
        </xsl:for-each>
        <xsl:text>&#10;</xsl:text>
    </xsl:for-each>
</xsl:template>

</xsl:stylesheet>