以最小成本断开无向加权图中的两个节点

Question

假设我们已经给出了一个无向加权图以及一个源节点和目标节点，我们需要通过删除边来断开源节点和目标节点的连接，并且删除边的成本是边的权重。 我们需要最小化断开两个节点的成本。

例如

在这里断开 0 节点和 6 节点需要 5 分钟的成本

Answer 1

使用答案集编程，您可以有效地以声明方式解决 NP 问题。

给定一个实例文件instance.lp来描述您的图形：

edge(0,1,5).
edge(1,2,3).                             
edge(2,5,3).                   
edge(5,6,4).
edge(1,3,4).           
edge(3,4,5).          
edge(4,6,6).                                                   
                                                      
source(0).                      
sink(6). 

以及描述您的问题的encoding.lp ：

%% chose a subset of the edges to remove 
{removed(X,Y,W) : edge(X,Y,W)}.
            
%% source is reachable 
reach(X) :- source(X).
%% going through edges is reachable if the edge ws not removed 
reach(Y) :- reach(X), edge(X,Y,W), not removed(X,Y,W).
%% handling bidirectional edges 
reach(Y) :- reach(X), edge(Y,X,W), not removed(Y,X,W).
                                                                                                                       
%% it is not allowed to reach the sink                                                                                 
:- sink(X), reach(X).                                                                                                  
                                                                                                                       
%% minimize the number of removed edges weighted by W                                                                  
#minimize {W,X,Y : removed(X,Y,W)}.                                                                                    
                                                                                                                       
%% show only removed edges                                                                                             
#show removed/3. 

调用clingo encoding.lp instance.lp （可从https://potassco.org/ 获得）产生输出：

clingo version 5.5.1
Reading from encoding.lp ...
Solving...
Answer: 1
removed(5,6,4) removed(4,6,6)
Optimization: 10
Answer: 2
removed(5,6,4) removed(1,3,4)
Optimization: 8
Answer: 3
removed(0,1,5)
Optimization: 5
OPTIMUM FOUND

最后一个答案是您问题的最佳解决方案。 您也可以简单地将这两个文件的内容复制到您的浏览器文本字段中以在此处试用（但性能会降低）。

Answer 2

LOOP
   Use Dijkstra to find min path from src to dst
   If no path found
      STOP
   Remove cheapest link on path