如何使用批处理脚本创建没有文件类型扩展名的文件夹名称并移入创建的子目录？

Question

帮帮我先生，我尝试了 100 多次，但它并不完全适合我。

目前以错误的方式获得结果：-
下面给出了批处理脚本从这个文件创建文件夹（7101-1 -kutana.pdf ）名称与.pdf扩展名但不完全是我需要的。

结果我需要以正确的方式a / q给出以下步骤

例如
第 1 步：-我想从文件名中删除第一个五个字符（7101- 1- kutana ）
而且我想从文件夹名称中删除扩展名。
源目录=e:\automovesystem\temp
A. 来源 pdf 文件名：- 7101-1- kutana.pdf

第2步：-
在1-(space)kutana的destdir名称下创建目录并授予
B. destdir=e:\automovesystem\prpl
创建目录e:\automovesystem\prpl\1- kutana\award

Step3.根据步骤1文件名检查文件夹名称是否可用。

第 4 步： - 将相同的文件移动到在第 2 步中创建的子目录下的同一文件夹中。

@echo off setlocal enableextensions disabledelayedexpansion 
Set "sourcedir=e:\automovesystem\temp" 
Set "destdir=e:\automovesystem\prpl"
For /f "eol=| tokens=1* delims=-" %%a in ('dir /b /a-d-h "%sourcedir%\*-*" 2^>nul') do ( 
Md "%destdir%\%%b\award" 2>nul 
Move /y "%sourcedir%\%%a-%%b" "%destdir%\%%b\award" )
Endlocal

Answer 1

除了您自己的答案之外，我可能会更像这样：

@Echo Off
SetLocal EnableExtensions

Set "SRC=E:\automovesystem\TEMP"
Set "DST=E:\automovesystem\PRPL"

If Not Exist "%SRC%\" (Exit /B) Else If Not Exist "%DST%\" Exit /B

For /F "Delims=" %%G In ('%SystemRoot%\System32\where.exe "%SRC%":"????-?*-?*.*"
 2^>NUL') Do For /F "Tokens=1,* Delims=-" %%H In ("%%~nG"
) Do %SystemRoot%\System32\Robocopy.exe "%%~dpG." "%DST%\%%I\NOTICE" "%%~nxG"^
 /Mov 1>NUL 2>&1

Answer 2

我自己做了它，我很高兴😅😍我对批处理脚本的了解较少，这就是为什么不从昨天开始睡觉继续努力制作 AutoMoveFilesystem 但我也非常感谢提供堆栈溢出平台来创建此代码。 我不能没有这个平台。

@Echo Off 

Set "SRC=E:\automovesystem\TEMP"
Set "DST=E:\automovesystem\PRPL"

SetLocal EnableDelayedExpansion
If Not Exist "%SRC%\" (Exit/B) Else If Not Exist "%DST%\" Exit/B
For /F "Delims=" %%A In ('Where "%SRC%":?????????*.*') Do (Set "FNX=%%~nA"
    If Not Exist "%DST%\!FNX:~5,50!\NOTICE" (MD "%DST%\!FNX:~5,50!\NOTICE" 2>Nul
        If ErrorLevel 1 Echo Unable to create directory %DST%\!FNX:~5,50!\NOTICE)
    If Exist "%DST%\!FNX:~5,50!\NOTICE" (Move /Y "%%A" "%DST%\!FNX:~5,50!\NOTICE">Nul 2>&1
        If ErrorLevel 1 Echo Unable to move %%A to %DST%\!FNX:~5,50!\NOTICE))
Timeout -1
Exit/B

Answer 3

这方面的所有帮助都归功于@XionicFire，他重新编写了整个代码，我只是将它发布给其他人使用/受益：

这段代码来自几个不同的人@PrahladDixit 和@Compo，代码不起作用我们无法解释为什么经过大量搜索后它似乎遭受了通常的影响......“一位专业人士写了这个，所以没有人明白什么他做到了”综合症，我们的蠕虫无法弄清楚，我们重新制作并组织了它，以便正常的人类“蠕虫”可以理解它在做什么并使它更友好一点，因此更容易根据需要进行修改和更改，我们希望这会有所帮助其他，在 windows 11 中效果很好

代码

@ECHO OFF
ECHO This file will create Individual folders inside the current folder using the following Parameters and sort all *.JPG files in current directory accordingly
REM To change target or source directory simply type it in the variable field
SET "SRC=%~dp0"
SET "SRC=%SRC:~0,-1%"
SET "DST=%~dp0"
SET "DST=%DST:~0,-1%"
ECHO. 
REM For Diagnostics & Troubleshooting Purposes
ECHO Source: %SRC%
ECHO Destination: %DST%
ECHO Characters: 19
ECHO Where: %SystemRoot%\System32\where.exe "%SRC%":*.jpg
ECHO. 
ECHO To Cancel this operation press CTRL-C
PAUSE
SetLocal EnableDelayedExpansion
If Not Exist "%SRC%\" (Exit/B) Else If Not Exist "%DST%\" Exit/B
For /F "Delims=" %%A In ('%SystemRoot%\System32\where.exe "%SRC%":*.jpg') Do (
    SET "FNX=%%~nA"
REM Replace 19 for the number of characters from the start of the filename you wish to use as Base for folder creation
    SET "FNX=!FNX:~,19!
REM For Diagnostics & Troubleshooting Purposes
REM ECHO !DST!\!FNX!\
    If Not Exist "!DST!\!FNX!\" (MD "!DST!\!FNX!" 2>NUL
        If ErrorLevel 1 ECHO Unable to create directory !DST!\!FNX!)
    If Exist "!DST!\!FNX!\" (MOVE /Y "%%A" "!DST!\!FNX!">NUL 2>&1
        If ErrorLevel 1 ECHO Unable to move %%A to !DST!\!FNX!)
    )
ECHO ************************ DONE ************************
PAUSE
REM Use in the case of running multiple scripts in a row
REM EXIT/B