使用 Parallels VM 将 Form 重新定位到第二台显示器时屏幕变黑

Question

我正在双显示器系统上的 Windows 10（在 Parallels 中虚拟化）中使用 Delphi 10.4.2。 要在多监视器系统上重现该问题，请创建一个新的 Windows VCL 应用程序并在窗体上放置两个按钮： btnPrimaryMonitor和btnSecondaryMonitor 。 然后通过为两个按钮创建单击处理程序来插入此代码：

procedure TForm1.btnPrimaryMonitorClick(Sender: TObject);
begin
  RepositionFormToMonitor(0);
  EnableDisableButtons;
end;

procedure TForm1.RepositionFormToMonitor(const aMonitor: Integer);
const
  offset = 2;
begin
  Self.Width := Screen.Monitors[aMonitor].Width - offset;
  Self.Height := Screen.Monitors[aMonitor].Height - offset;

  Self.Top := Screen.Monitors[aMonitor].Top;
  Self.Left := Screen.Monitors[aMonitor].Left;
end;

procedure TForm1.btnSecondaryMonitorClick(Sender: TObject);
begin
  RepositionFormToMonitor(1);
  EnableDisableButtons;
end;

procedure TForm1.FormShow(Sender: TObject);
begin
  EnableDisableButtons;
  Self.BorderStyle := bsNone;
  Self.FormStyle := fsStayOnTop;
  RepositionFormToMonitor(0);
end;

procedure TForm1.EnableDisableButtons;
begin
  btnPrimaryMonitor.Enabled := (Self.Monitor.MonitorNum = 1);
  btnSecondMonitor.Enabled := (Self.Monitor.MonitorNum = 0);
end;

这工作得很好，但是一旦我设置了offset = 1或offset = 0屏幕就会变黑！

代码的目的是通过点击从主监视器重新定位最大化停留在最上层的模架在辅助监视器btnSecondMonitor按钮，然后再返回到主监视器通过点击btnPrimaryMonitor按钮。

如何避免这个问题？

Answer 1

几个问题：

1. 您不应将WindowState设置为wsMaximized 。 事实上，你根本不应该碰这个属性。

2. 设置BoundsRect将设置Left 、 Top 、 Width和Height ，因此无需分别设置Left和Top 。

3. 要返回主监视器，只需设置表单的BoundsRect 。

下面是一个例子：

创建一个新的 VCL 项目。 将主窗体的BorderStyle为bsNone 。

然后添加以下代码：

procedure TForm1.FormCreate(Sender: TObject);
begin
  for var i := 0 to Screen.MonitorCount - 1 do
  begin
    var btn := TButton.Create(Self);
    btn.Parent := Self;
    btn.Caption := i.ToString;
    btn.Tag := i;
    btn.OnClick := MonitorButtonClick;
    btn.Top := 8;
    btn.Left := 8 + (btn.Width + 8) * i;
  end;
end;

procedure TForm1.MonitorButtonClick(Sender: TObject);
begin
  BoundsRect := Screen.Monitors[(Sender as TButton).Tag].BoundsRect;
end;

如果此代码在您的系统上无法正常工作，则您的 Windows 系统可能存在一些问题。 这应该完美无缺。