广播分配了很多 memory whist for loop 没有

Question

如果我有以下两种变体来编写我的代码的一部分，我通常更喜欢较短的一种。 这就是为什么我喜欢在 Julia 中进行点播的原因。 但是我有这个例子表明它有问题。

function test1(A)
    n = size(A, 2)
    for k in 1:n
        for i in k+1:n
            A[i, k] /= A[k, k]
        end
    end
    A
end

function test2(A)
    n = size(A, 2)
    for k in 1:n
        A[k+1:n, k] ./= A[k,k]
    end
    A
end

A = rand(10000,10000)
B = copy(A)
@allocated test1(B) # returns 0
C = copy(A)
@allocated test2(C) # returns 401131136
C == B # returns true

此外，我试图消除语法糖并再写一个测试 function

function test3(A)
    n = size(A, 2)
    for k in 1:n
        broadcast!(/, A[k+1:n, k], A[k+1:n, k], A[k,k])
    end
    A
end

而这个分配的 memory 是test2的两倍，并且......返回错误的结果。

为什么test3返回错误的结果，广播有什么问题，有没有指南解释如何使用它？

Answer 1

问题是在A[k+1:n, k]./= A[k,k]你可以认为它被重写为：

A[k+1:n, k] .= A[k+1:n, k] ./ A[k,k]

现在的重点是，在A[k+1:n, k]./ A[k,k]部分中， A[k+1:n, k]部分在执行除法之前复制了数组。 原因是安全。 您可以通过显式创建视图而不是副本来覆盖它：

function test2_fix(A)
    n = size(A, 2)
    for k in 1:n
        A[k+1:n, k] .= view(A, k+1:n, k) ./ A[k,k]
    end
    A
end

broadcast! call 更糟糕且不正确，因为A[k+1:n, k]在将值传递给broadcast! 所以你的源数组A不会受到影响

Answer 2

我将分解语法最终的含义。 这是你的第一次广播尝试和它的等价物（嗯， Meta.@lower中的步骤有点不同，但它对Array做同样的事情）：

A[k+1:n, k] ./= A[k,k]
A[k+1:n, k] .= A[k+1:n, k] ./ A[k,k]
broadcast!(/, @view(A[k+1:n, k]), A[k+1:n, k], A[k,k])

注意.= broadcast! 设置为将结果写入左侧数组A的视图。 视图访问数组的 memory，从 v1.5 开始，它是非分配的。 您第二次尝试broadcast! 错过了这个细节，所以你最终写入了一个新数组而不是A 。

问题是切片括号语法，例如A[k+1:n, k] ，确实getindex 。 如果getindex正在访问 >1 的值，它会分配一个新数组并将值复制到其中，因此在这种情况下，您希望使用view而不是getindex 。 以下是执行此操作的等效方法：

broadcast!(/, @view(A[k+1:n, k]), @view(A[k+1:n, k]), A[k,k])
A[k+1:n, k] .= @view(A[k+1:n, k]) ./ A[k,k]

@view(A[k+1:n, k]) ./= A[k,k]
@views A[k+1:n, k] ./= A[k,k]

@view宏允许您使用切片括号语法来调用view而不是getindex 。 @views宏是一种将以下表达式中的所有切片括号语法转换为使用view而不是getindex的方法。