在批处理文件中使用时找不到 wsl 命令

Question

我想在登录时使用批处理脚本在 wsl 中启动 docker。 当我以管理员身份调用文件时，它可以工作。 因此，我遵循了本指南： https://www.thewindowsclub.com/run-as-administrator-for-batch-files然后我将快捷方式放入启动文件夹。 该脚本已启动，但它在第一行崩溃。 然后我尝试手动运行批处理文件，并出现以下问题：当我通过右键单击以管理员身份运行脚本时，脚本有效。 当我双击运行它时，我得到“命令“wsl”拼写错误或找不到”。

这是脚本：

FOR /F "tokens=* USEBACKQ" %%g IN (`wsl.exe sh -c "hostname -I"`) do (SET "ip=%%g")
netsh interface portproxy add v4tov4 listenport=2375 connectport=2375 connectaddress=%ip%
wsl sh -c "sudo dockerd -H tcp://%ip%"

我已经尝试完全删除 wsl 并重新安装它，但问题仍然存在。

Answer 1

应首先阅读以下 Microsoft 文档页面：

• WOW64 实施细节
• 文件系统重定向器
• 受 WOW64 影响的注册表项

采用 AMD64 架构处理器的 64 位 Windows 上有两个系统目录：

1. %SystemRoot%\System32与 64 位应用程序默认使用的 64 位应用程序。
2. %SystemRoot%\SysWOW64与 32 位应用程序默认使用的 32 位应用程序。

系统环境变量PATH包含 Windows 默认%SystemRoot%\System32作为第一个文件夹路径。 如果 32 位应用程序启动cmd.exe来处理批处理文件，则由于文件系统重定向器而启动了 32 位%SystemRoot%\SysWOW64\cmd.exe 。

cmd.exe正在使用本地环境变量PATHEXT和PATH搜索批处理文件中指定的文件，该文件仅具有不带或带文件扩展名且不带路径的文件名，如“X 未被识别为内部或外部命令、可运行程序或批处理文件”？

wsl.exe属于在 AMD64 Windows 上仅作为%SystemRoot%\System32中的 64 位版本存在的可执行文件集。 由于文件系统重定向器，在本地PATH中使用扩展形式的%SystemRoot%\System32时，32 位cmd.exe搜索到%SystemRoot%\SysWOW64中没有 32 位版本。 因此，问题中发布的批处理文件不适用于由 Windows x64 上的 32 位cmd.exe处理。

该解决方案将 WOW64 与批处理文件中的附加代码考虑在内：

@echo off
setlocal EnableExtensions DisableDelayedExpansion
if exist %SystemRoot%\System32\wsl.exe set "FileNameWSL=%SystemRoot%\System32\wsl.exe" & goto RunWSLCommands
if exist %SystemRoot%\Sysnative\wsl.exe set "FileNameWSL=%SystemRoot%\Sysnative\wsl.exe" & goto RunWSLCommands
echo ERROR: Could not find wsl.exe. Script execution aborted.
@setlocal EnableDelayedExpansion & for /F "tokens=1,2" %%G in ("!CMDCMDLINE!") do @endlocal & if /I "%%~nG" == "cmd" if /I "%%~H" == "/c" pause
exit /B
:RunWSLCommands
for /F "tokens=*" %%g in ('%FileNameWSL% sh -c "hostname -I"') do set "ip=%%g"
%SystemRoot%\System32\netsh.exe interface portproxy add v4tov4 listenport=2375 connectport=2375 connectaddress=%ip%
%FileNameWSL% sh -c "sudo dockerd -H tcp://%ip%"
endlocal

要了解使用的命令及其工作原理，请打开命令提示符window，在其中执行以下命令，并仔细阅读每个命令显示的所有帮助页面。

• echo /?
• endlocal /?
• exit /?
• for /?
• goto /?
• if /?
• netsh /?
• netsh interface /?
• netsh interface portproxy /?
• netsh interface portproxy add /?
• netsh interface portproxy add v4tov4 /?
• pause /?
• set /?
• setlocal /?