尝试水平批量合并 2.jpeg，然后将它们放在不同的文件夹中

Question

这是我的医学博士论文。 所以请原谅我在编程方面的菜鸟。 我有一堆（大约 4000 个文件）来自患者的扫描。 每个患者都有一个 front 和 back.jpg。 那里每天有多名患者。 文件夹结构如下所示：

\images
    \2017-08-21
              \pa_102165.jpg
              \pa_10216500001.jpg
    \2017-06-14
              \pa_101545.jpg
              \pa_10154500001.jpg
              \pa_104761.jpg
              \pa_10476100001.jpg
              \pa_107514.jpg
              \pa_10751400001.jpg
    \2017-03-73
              \pa_109631.jpg
              \pa_10963100001.jpg
              \pa_108624.jpg
              \pa_10862400001.jpg

在第一个示例中， 2017-08-21是患者进来的日期， pa_102165.jpg是前面， pa_10216500001.jpg是后面。 所以前面总是pa_10XXXX.jpg后面是pa_10XXXX00001.jpg 。 我没有参与命名方案。

我的目标是制作一个批处理脚本，将每个患者的 2 个对应 .jpg 水平合并并自动将它们放在不同的文件夹中，这样我就不必使用 MS Paint 之类的东西手动完成。 例如像这样：

\images
\merged
        \2017-08-21
                      \pa_102165_merged.jpg
        \2017-06-14
                      \pa_101545_merged.jpg
                      \pa_104761_merged.jpg
                      \pa_107514_merged.jpg
        \2017-03-73
                      \pa_109631_merged.jpg
                      \pa_108624_merged.jpg

我正在研究 Windows 10，到目前为止发现了两种有前途的方法，但无法理解如何将其制成批处理文件或类似的东西。

IrfanView Thumbnails
    1. Mark the 2 corresponding .jpgs
    2. File>Create contact sheet from selected files...
    3. Create
    4. File>Save as... in destination folder which i have to create for every day

这比手动合并它们要快，但会花费多个工作日来处理所有对

和...

ImageMagic in Windows cmd
        C:\Users\me\doctor\Images\test\images\2016-03-31>convert pa_102165.jpg pa_10216500001.jpg +append pa_102165_merged.jpg

这会在输入图像所在的同一文件夹中生成merged.jpeg。这看起来更有希望，但我无法掌握如何在给定命名方案和文件夹结构的情况下自动执行此过程。

感谢您抽时间阅读！ 我为你的每一个输入感到高兴！

Answer 1

这应该让你相当接近。 本质上，它使用FOR命令修饰符的功能来提取基本文件名和文件扩展名。 FOR /F命令正在捕获通过管道传输到FINDSTR命令的DIR命令的 output。 我们这样做是为了只抓取文件掩码为pa_######.jpg的文件

一旦我们有了，我们使用命令修饰符和IF命令来确保00001文件存在。 如果它确实存在，那么它将执行转换命令。 为了确保代码正确执行，我只是将ECHOING回显到屏幕上。 如果屏幕上的 output 看起来正确，则删除ECHO以便执行CONVERT命令。

@echo off

CD /D "C:\Users\me\doctor\Images\test\images"

FOR /F "delims=" %%G IN ('DIR /A-D /B /S PA_*.jpg ^|findstr /RIC:"pa_[0-9][0-9][0-9][0-9][0-9][0-9]\.jpg$"') DO (
    IF EXIST "%%~dpnG00001%%~xG" (
        ECHO convert "%%G" "%%~dpnG00001%%~xG" +append "%%~dpnG_merged%%~xG"
    )
)

Answer 2

可以使用IrfanView完成此任务，并将以下批处理文件存储在包含文件夹images的目录中。

@echo off
setlocal EnableExtensions DisableDelayedExpansion
set "IrfanView=%ProgramFiles(x86)%\IrfanView\i_view32.exe"
set "SourcePath=%~dp0images"
set "TargetPath=%~dp0merged"
for /F "delims=" %%I in ('%SystemRoot%\System32\where.exe /R "%SourcePath%" pa_10????.jpg  2^>nul') do for %%J in ("%%~dpI.") do (
    if not exist "%TargetPath%\%%~nxJ\%%~nI_merged%%~xI" if exist "%%~dpnI00001%%~xI" (
        if not exist "%TargetPath%\%%~nxJ\" md "%TargetPath%\%%~nxJ"
        if exist "%TargetPath%\%%~nxJ\" (
            echo Merging "%%~nxJ\%%~nxI" and "%%~nxJ\%%~nI00001%%~xI" ...
            "%IrfanView%" /convert="%TargetPath%\%%~nxJ\%%~nI_merged%%~xI" /jpgq=95 /panorama=(1,"%%I","%%~dpnI00001%%~xI"^)
        )
    )
)
endlocal

第三行必须自定义IrfanView的全限定文件名。 还可以修改选项/jpgq的百分比值，它定义了 output JPEG 文件的质量。

命令WHERE在包含批处理文件的目录的子目录images中递归搜索匹配通配符模式pa_10????.jpg的文件，而忽略所有其他文件。 找到的文件名是 output 和完整路径，这个文件名列表被FOR捕获并在WHERE完成后逐行处理。 在这种情况下， WHERE由另外一个cmd.exe在后台启动，选项/c和'中的命令行作为附加的 arguments 执行，而不是由处理批处理文件的cmd.exe执行。

阅读有关使用命令重定向运算符的 Microsoft 文档，了解2>nul的说明。 当 Windows 命令解释器在执行命令FOR执行嵌入的where命令行并使用在后台启动的单独命令进程之前处理此命令行时，重定向运算符>必须在FOR命令行上使用脱字符^进行转义以解释为文字字符。

每个具有全名（驱动器 + 路径 + 名称 + 扩展名）的图像文件一个接一个地分配给循环变量I 。 对于每个文件名，再使用一个FOR循环，该循环仅处理当前图像文件的完整路径，以分配此路径，并在循环变量J后附加一个点。 末尾的点表示当前目录，即包含当前要处理的图像文件的目录。

接下来检查第一个IF条件，如果该图像文件不存在匹配的pa_10????_merged.jpg文件，在这种情况下，当前图像文件无事可做。 这意味着批处理文件可以根据需要在同一个文件夹中执行，因为它仅针对不存在相应目标 JPEG 文件的源 JPEG 文件运行IrfanView 。

第二个IF条件检查后图像是否也存在于当前前图像的目录中，否则根本无法合并任何内容。

如果目标目录已经存在，接下来将使用第三个IF条件进行检查，如果不存在则创建此目录。

最后一个IF条件再次检查目标目录是否存在，如果现在按预期存在，则使用适当的选项调用IrfanView以在目标目录中创建具有适当文件名的合并图像文件。

IrfanView命令行上的右圆括号)必须用^转义，以便由cmd.exe逐字解释，以将此右括号传递给IrfanView ，而不是将其解释为以(上面打开的命令块之一的结尾。

要了解使用的命令及其工作原理，请打开命令提示符window，在其中执行以下命令，并仔细阅读每个命令显示的所有帮助页面。

• call /? ... 解释%~dp0 ... 参数 0 的驱动器和路径，它是批处理文件路径，总是以反斜杠结尾
• echo /?
• endlocal /?
• for /?
• if /?
• md /?
• setlocal /?
• where /?

双击IrfanView的程序文件夹中的文本文件i_options.txt以了解批处理文件中使用的IrfanView选项的描述。