如果文件中已经存在该行，如何避免将行插入文件？

Question

应该如何进行检查以使文件中没有重复行

open ( FILE, ">newfile");
for( $a = 1; $a < 20; $a = $a + 1 ) {
    my $random_number = 1+ int rand(10);;
    # check to avoid inserting the line if the line is already present in the file
    print FILE "Random number is $random_number \n";
}

close(FILE);

Answer 1

似乎您要问的是如何随机化数字 1 到 20 的顺序。即没有重复，随机顺序。 这可以通过Schwartzian 变换轻松完成。 例如：

perl -le'print for map { $_->[0] } sort { $a->[1] <=> $b->[1] } map { [$_, rand()] } 1..20'
6
7
16
14
5
20
3
13
19
17
4
8
15
10
9
11
18
1
2
12

在这种情况下，从末尾和向后读取，我们创建一个数字列表 1.. 20，我们将其输入到map语句中，该语句将每个数字转换为数组引用，包含数字和随机数。 然后我们将该数组 ref 的列表提供给一个排序，在这里我们对数组 ref 中的第二个参数进行数字排序：随机数（因此创建一个随机顺序）。 然后我们使用另一个map语句将数组 ref 转换回一个简单的数字。 最后，我们使用for循环打印列表。

所以在你的情况下，代码看起来像：

print "Random number is: $_\n" for      # print each number
    map { $_>[0] }                      # restore to a number
    sort { $a->[1] <=> $b->[1] }        # sort the list on the random number
    map { [ $_, rand() ] }              # create array ref with random number as index
    1 .. 20;                            # create list of numbers to randomize order of

然后您可以使用如下程序将 output 重定向到文件：

$ perl numbers.pl > newfile.txt

Answer 2

将每一行也输入到 hash 中，这使得以后检查变得容易和高效

use warnings;
use strict;
use feature 'say';

my $filename = shift or die "Usage: $0 filename\n";

open my $fh, '>', $filename or die "Can't open $filename: $!";

my %existing_lines;

for my $i (1..20) 
{ 
    my $random_number = 1 + int rand(10);

    # Check to avoid inserting the line if it is already in the file
    if (not exists $existing_lines{$random_number}) { 
        say $fh "Random number is $random_number";
        $existing_lines{$random_number} = 1;
    }   
}

Answer 3

return false就可以了。

因为您无法在 [1, 10] 范围内生成 20 个不同的数字。

Answer 4

!$seen{$_}++是识别重复项的常用习语。

my %seen;
for (1..19) { 
    my $random_number = 1+ int rand(10);

    say "Random number is $random_number" if !$seen{$random_number}++;
}

但这并不能保证您会以随机顺序获得从 1 到 10 的所有数字。 如果这就是您要实现的目标，那么以下是一个更好的解决方案：

use List::Util qw( shuffle );

say "Random number is $_" for shuffle 1..10;