如何验证这种类型的变量？

Question

我得到了代码：

this.socket.connect("127.0.0.1",1000);

如果 ip 或端口不同，我想执行 function securityError

就像代码一样

this.socket.connect("129.124.7.17",1000);

或者

this.socket.connect("127.0.0.1",1236);

或者他们两个都不同做 function securityError

我在想它应该看起来像这样：

if(this.socket.connect != ("127.0.0.1",1000))
{
this.securityError
}

Answer 1

答案是……事件处理。

但首先，让我们学习一下，什么是事件以及我们为什么需要它们。

Flash Player是一个平台，它以某种特定的逐帧方式运行其应用程序，无休止地重复相同的循环：

1. 执行脚本（ MovieClip的帧脚本和自上一帧以来发生的所有事件）。
2. 渲染显示列表（包括脚本执行的结果以及通过设计逐帧更改的内容，例如MovieClip的时间线）并显示渲染结果。

在脚本执行阶段结束之前，渲染阶段不会开始。 如果你放一些无限运行的脚本，渲染阶段根本不会开始：

while (true)
{
    // Do nothing.
}

它与 sockets 有什么关系？ 问题是，有些操作（大部分与外部环境有关）不能保证在给定时间内完成（或根本完成）：

• 从本地驱动器加载文件。
• 通过HTTP请求发送和接收数据。
• （以及）连接到TCP套接字，向/从其发送和接收数据。

如果您在脚本执行阶段尝试等待这些（和其他类似）操作完成，您可能会完全停止您的应用程序。

那么，你如何避免这样的结局呢？

答案是：异步操作和事件。 您应该以类似多线程的方式思考，并将您的AS3逻辑组合在一小块代码中，这些代码启动非保证操作并完成脚本以允许渲染阶段发生，而其他代码块在何时执行在这些长期运行的非保证操作执行其操作时，出现了一些问题。 重要的是它不重要， WHEN 。 我们只是假设它会在一段时间后发生。

让我们看一些例子：

// WARNING: This one snippet is NOT a real AS3 code,
// just an example of synchronous thinking.

function loadSettings(fileName:String):void
{
    var aSettings:String = LocalFile.load(fileName);
    
    if (aSettings)
    {
        // The file was loaded successfully, process the loaded data.
    }
    else
    {
        // The file failed to load. React to it.
    }
}

然后，它是如何在AS3中真正完成的：

function loadSettings(fileName:String):void
{
    // Here I let the aLoader be a local function variable,
    // yet keep in mind that you ALWAYS need to store such
    // an object attached to scope in some way. Otherwise
    // the Garbage Collector might just eat it away.
    var aLoader:URLLoader = new URLLoader;
    
    // Subscribe to events of the loading process.
    
    // Successful loading.
    aLoader.addEventListener(Event.COMPLETE, onSettings);
    
    // Error cases.
    aLoader.addEventListener(IOErrorEvent.IO_ERROR, onFailed);
    aLoader.addEventListener(SecurityErrorEvent.SECURITY_ERROR, onFailed);
    
    // Start asynchronous loading process.
    aLoader.load(new URLRequest(fileName));
    
    // The script is done here.
}

让我们处理这些事件。

function onSettings(e:Event):void
{
    // Event ALWAYS has a reference to the object,
    // but you need to typecast it to the appropriate class.
    var aLoader:URLLoader = e.target as URLLoader;
    
    // The file was loaded successfully, process the loaded data.
}

function onFailed(e:Event):void
{
    var aLoader:URLLoader = e.target as URLLoader;
    
    // The file failed to load. React to it.
}

如您所见，两种情况下的逻辑完全相同，但事件处理允许文件加载根据需要花费尽可能多的时间，而不会使Flash 播放器卡顿。

我还鼓励您搜索类似as3 事件解释的内容并阅读所有相关教程。

与您的 sockets 完全相同。 您有几个可能有效的主机：端口对，您希望您的脚本连接到任何可用的，您需要停止单线程思考并开始思考事件：

var aSock:Socket;

var aList:Array = [
    {host:"127.0.0.1", port:1000},
    {host:"127.0.0.1", port:1236},
    {host:"129.124.7.17", port:1000},
];

function tryNext():void
{
    // Create a new socket instance.
    aSock = new Socket;
    
    // Subscribe to possible outcomes.
    aSock.addEventListener(Event.CONNECT, onConnected);
    aSock.addEventListener(IOErrorEvent.IO_ERROR, onFailed);
    aSock.addEventListener(SecurityErrorEvent.SECURITY_ERROR, onFailed);
    
    // Try connecting to the next server from the list.
    var aServer:Object = aList[0];
    
    // Start the asynchronous operation.
    aSock.connect(aServer.host, aServer.port);
}

// Handle the failed-to-connect case.
function onFailed(e:Event):void
{
    // Sanity check: ignore the event, if
    // it is not from the current socket object.
    var aSocket:Socket = e.target as Socket;
    if (aSocket != aSock) return;
    
    // Remove the failed server from the list.
    aList.shift();
    
    // Try next server, if there are any left.
    if (aList.length)
    {
        tryNext();
    }
    else
    {
        // None of the given servers responded.
        // Process the case here.
    }
}

// Handle the failed-to-connect case.
function onConnected(e:Event):void
{
    // Sanity check, again.
    var aSocket:Socket = e.target as Socket;
    if (aSocket != aSock) return;
    
    // If we're here, that means everything is fine and the socket aSock
    // is successfully connected to the server with the host:port pair
    // from the aList[0] object. You can start reading and writing
    // data from/to socket from here on.
}

Answer 2

我在想它应该看起来像这样：

if( this.socket.connect != ("127.0.0.1",1000) )
{
    this.securityError
}

如果您正在制作 AIR 项目（即：谁再为浏览器制作 SWF？？）您可能想查看Socket命令，其中remotePort和remoteAddress之类的东西可能对您有用（确保this.socket存在并注意您的this.securityError代码不会做任何事情，如果连接不正确，您需要抛出错误或执行下一步）：

if( (this.socket.remoteAddress != "127.0.0.1") && (this.socket.remotePort != 1000) )
{
   this.securityError
}