如何将 AS3 中的关键字原型翻译成 Haxe？

Question

我有下面的 AS3 代码，我想把它翻译成 Haxe。 但我不知道如何处理关键字prototype 。 谁能帮我？ 谢谢。

    var style = new CSSStyleDeclaration(); 
    style.defaultFactory = function():void
    {
       this.disabledOverlayAlpha = 0;
       this.borderStyle = "controlBar";
       this.paddingTop = 10;
       this.verticalAlign = "middle";
       this.paddingLeft = 10;
       this.paddingBottom = 10;
       this.paddingRight = 10;
    };
    if(chain == null) chain = {};
    style.defaultFactory.prototype = chain;
    chain = new style.defaultFactory();
    

Answer 1

好的，我戳了一下，现在我有点想通了，那段代码的作用。 这些知识不会帮助您将代码移植到HAXE ，但它将帮助您了解它的含义并编写一个像样的HAXE风格的替代方案。

首先，关于实例化、函数和使用原型的部分。 事实证明，如果您在未绑定的 function 上调用new运算符（不适用于 class 方法）：

1. 创建了新的空无类通用Object 。
2. 它的引用被传递给上述 function 作为this 。
3. function可以添加和修改对象的字段和方法。
4. 最终，返回对Object的引用。

然后，它的工作方式（正如我在上面的评论中提到的）非常类似于当时在AS1和Flash 6中的类工作方式。

If that function has a prototype and it is too a generic Object , then it is added to the newly created one as a... how to put it... a bottom layer Object which adds its fields to the top layer Object .

我知道这听起来很困难，所以有一个解释性的例子可以以某种方式阐明这一切：

public class Proton extends Sprite
{
    
    public function Proton() 
    {
        super();
        
        var P:Function;
        
        // Empty.
        P = new Function;
        create("First:", P);
        
        // Empty with prototype.
        P.prototype = {c:3, d:4};
        create("Second:", P);
        
        // Non-empty.
        P = function():void
        {
            this.a = 1;
            this.b = 2;
        };
        create("Third:", P);
        
        // Non-empty with prototype.
        P.prototype = {a:5, f:6};
        create("Fourth:", P);
    }
    
    // Instantiates the F and outputs the result.
    private function create(prefix:String, F:Function):void
    {
        var A:Object = new F;
        
        trace(prefix + "\nJSON:" + JSON.stringify(A) + "\nREAL:" + explore(A) + "\n");
    }
    
    // Same as JSON.stringify, but also looks into the prototype.
    private function explore(O:Object):String
    {
        var result:Array = new Array;
        
        for (var akey:String in O)
        {
            result.push('"' + akey + '":' + O[akey]);
        }
        
        return "{" + result.join(",") + "}";
    }
}

所以，output 是：

First:
JSON:{}
REAL:{}

Second:
JSON:{}
REAL:{"d":4,"c":3}

Third:
JSON:{"b":2,"a":1}
REAL:{"b":2,"a":1}

Fourth:
JSON:{"b":2,"a":1}
REAL:{"b":2,"a":1,"f":6,"a":1}

如您所见， JSON.stringify仅导出顶层object，而直接迭代遍历所有层，从上到下，甚至处理重复键（但顶层值遮住了下面的内容）。

其次，这一切与您的代码有何关系。 These factory and defaultFactory functions are used in some CSS -related class to form an Object representation of the style: https://help.adobe.com/en_US/FlashPlatform/reference/actionscript/3/mx/styles/CSSStyleDeclaration.html

因此，您可以使用该原型破解来形成一个通用的Object ，其中包含一层又一层的 CSS声明……可能。 您看到JSON除了顶层之外什么都没有，我不知道CSS类的行为是否不同。

我认为，与CSS一起工作应该更简单，更直接。

祝你好运。