在链接到 CMake 目标时运行脚本

Question

我有一种情况，当 CMake 目标链接到时，我需要运行脚本，以便它可以在当前项目目录中自动生成用于与库交互的文件。

我知道当您链接到 CMake 目标时，它会自动拉入库的标头，以便它们对编译器可见，但我还需要它在链接对象的目录中生成一些文件，这些文件也将在编译器可见建造。

我如何告诉 CMake 每次my_cmake_target链接到时我想运行一个脚本来生成文件？

CMakeLists.txt 中的链接示例：

target_link_libraries(my_executable PRIVATE my_cmake_target)

我希望命令在 CMake 基于传递给“target_link_libraries”的目标传递更新包含目录的同时运行。 （在任何构建/链接实际发生之前）

有关其工作原理的更多信息，请参见此处：

https://schneide.blog/2016/04/08/modern-cmake-with-target_link_libraries/

使用 target_link_libraries 将 A 链接到内部目标 B 不仅会添加链接到 B 所需的 linker 标志，而且还会添加定义、包括路径和其他设置——即使是传递的——如果它们是这样配置的。

Answer 1

不幸的是，没有任何内置功能可以帮助您做到这一点。 通过接口属性传播自定义命令并不是 CMake 已经实现（或计划实现，afaik）。

但是，这有点被诅咒，这是一种方法。

您创建一个 function 扫描目录以查找链接到您的特殊库的可执行目标。 对于这些目标中的每一个，它都会在二进制目录中附加一个特殊的源文件和一个用于生成该文件的命令。 然后，使用cmake_language(DEFER CALL...)在当前目录的构建脚本末尾运行 function。 这部分确保 function 不必手动调用，即使在find_package场景中也是如此。

注意事项：

1. 这取决于您的库是否链接到可执行目标：
   1. 直接（即不及物）和
   2. 无条件（即不在生成器表达式中）
2. 它仅适用于同一目录中的目标。
3. 链接到当前目录之外的特殊库也会导致命令丢失。
4. 它要求将目标命名为有效的文件名。

---

cmake_minimum_required(VERSION 3.22)
project(example LANGUAGES CXX)

# Dark magic

function (MyProj_post_build)
  get_property(targets DIRECTORY . PROPERTY BUILDSYSTEM_TARGETS)
  foreach (target IN LISTS targets)
    get_property(type TARGET ${target} PROPERTY TYPE)
    if (NOT type STREQUAL "EXECUTABLE")
      continue ()
    endif ()

    get_property(libs TARGET ${target} PROPERTY LINK_LIBRARIES)
    if (";${libs};" MATCHES ";my_cmake_target;")
      add_custom_command(
        OUTPUT "MyProj_${target}.cpp"
        COMMAND "${CMAKE_COMMAND}" -E echo "const char* Name = \"$<TARGET_PROPERTY:${target},NAME>\";" > "MyProj_${target}.cpp"
        VERBATIM
      )
      target_sources(${target} PRIVATE "${CMAKE_CURRENT_BINARY_DIR}/MyProj_${target}.cpp")
    endif ()
  endforeach ()
endfunction ()

cmake_language(DEFER CALL MyProj_post_build)

# Normal stuff

add_library(my_cmake_target INTERFACE)

add_executable(my_executable main.cpp)
target_link_libraries(my_executable PRIVATE my_cmake_target)

add_executable(excluded main.cpp default-name.cpp)

这是它有效的证据......

$ cat main.cpp
#include <iostream>

extern const char* Name;

int main () { std::cout << Name << "\n"; }

$ cat default-name.cpp
const char* Name = "default";

$ cmake -G Ninja -S . -B build
[1/7] cd /home/alex/test/build && /usr/bin/cmake -E echo "const char* Name = \"my_executable\";" > MyProj_my_executable.cpp
[2/7] /usr/bin/c++    -MD -MT CMakeFiles/excluded.dir/default-name.cpp.o -MF CMakeFiles/excluded.dir/default-name.cpp.o.d -o CMakeFiles/excluded.dir/default-name.cpp.o -c /home/alex/test/default-name.cpp
[3/7] /usr/bin/c++    -MD -MT CMakeFiles/my_executable.dir/MyProj_my_executable.cpp.o -MF CMakeFiles/my_executable.dir/MyProj_my_executable.cpp.o.d -o CMakeFiles/my_executable.dir/MyProj_my_executable.cpp.o -c /home/alex/test/build/MyProj_my_executable.cpp
[4/7] /usr/bin/c++    -MD -MT CMakeFiles/excluded.dir/main.cpp.o -MF CMakeFiles/excluded.dir/main.cpp.o.d -o CMakeFiles/excluded.dir/main.cpp.o -c /home/alex/test/main.cpp
[5/7] /usr/bin/c++    -MD -MT CMakeFiles/my_executable.dir/main.cpp.o -MF CMakeFiles/my_executable.dir/main.cpp.o.d -o CMakeFiles/my_executable.dir/main.cpp.o -c /home/alex/test/main.cpp
[6/7] : && /usr/bin/c++   CMakeFiles/my_executable.dir/main.cpp.o CMakeFiles/my_executable.dir/MyProj_my_executable.cpp.o -o my_executable   && :
[7/7] : && /usr/bin/c++   CMakeFiles/excluded.dir/main.cpp.o CMakeFiles/excluded.dir/default-name.cpp.o -o excluded   && :

$ ./build/my_executable
my_executable

$ ./build/excluded 
default