For_each 和 count 在相同的 terraform AWS 资源中

Question

我正在尝试在 terraform 中创建“ aws_route ”，并使用另一个服务的 vpc_peering 遍历 route_tables 列表。 另一个服务 vpc destination_cidr_block是一个列表。

variable "route_tables" {
  type        = set(string)
  description = "Set of route table entries eg : rt-1, rt-2 , rt-3"
}


variable "ext_service_destination_cidr_blocks"{
  type = list(string)
  description = "list of destination cidr blocks of external service, eg:[\"10.10.1.1/20\", \"10.2.10.1/10\"]"
}


resource "aws_route" "ext_service_route" {
 // iterating over route tables [ rt-1, rt-2 , rt-3 ]
  for_each = var.route_tables
  route_table_id = each.key

// Iterating over cidr list 
  count = var.ext_service_destination_cidr_blocks
  destination_cidr_block = var.ext_service_destination_cidr_blocks[count.index]
  vpc_peering_connection_id = var.ext_service_peering_connection_id
}

在这里，我想遍历destination_cidr_block列表。 简单地说，我需要一个嵌套循环，在 for_each 中计数。 我不能在同一个块中同时拥有 count 和 for_each ，有什么解决方法吗？ 或者有什么办法可以把它分成两个模块？

Answer 1

我们可以使用setproduct计算这两个 collections 的笛卡尔积，并在此基础上创建一个map 。 这个map可以用来做for_each就可以了：

resource "aws_route" "ext_service_route" {
  for_each                  = { for i, pair in tolist(setproduct(var.route_tables, var.ext_service_destination_cidr_blocks)) : "route-${i}" => { "name" : pair[0], "cidr" : pair[1] } }
  route_table_id            = each.value.name
  destination_cidr_block    = each.value.cidr
  vpc_peering_connection_id = var.ext_service_peering_connection_id
}

Answer 2

您还可以使用mod操作同时迭代两个列表（例如，当您使用尚不支持for_each的旧 TF 版本时）：

resource "aws_route" "ext_service_route" {
  count                     = length(var.ext_service_destination_cidr_blocks) * length(var.route_tables)
  route_table_id            = element(var.route_tables, count.index + 1 % length(var.route_tables))
  destination_cidr_block    = element(var.ext_service_destination_cidr_blocks, count.index + 1 % length(var.ext_service_destination_cidr_blocks))
  vpc_peering_connection_id = var.ext_service_peering_connection_id
}