如何在 Perl 中转义字符串以进行 LDAP 搜索？

Question

我想根据 RFC 4515 转义一个字符串。因此，字符串“u1”将转换为“\75\31”，即每个字符的序数值，以十六进制表示，前面是反斜杠。

必须在 Perl 中完成。 我已经知道如何在 Python、C++、Java 等中做到这一点，但 Z01144306D73298F78

此外，我不能使用 Net::LDAP 并且我可能无法添加任何新模块，因此，我想使用基本的 Perl 功能来做到这一点。

Answer 1

通过 RFC 4515 略读，此编码转义了多字节 UTF-8 字符的各个八位字节，而不是代码点。 因此，也适用于非 ASCII 文本：

#!/usr/bin/env perl
use strict;
use warnings;
use feature qw/say/;

sub valueencode ($) {
    # Unpack format returns octets of UTF-8 encoded text
    my @bytes = unpack "U0C*", $_[0];
    sprintf '\%02x' x @bytes, @bytes;
}

say valueencode 'u1';
say valueencode "Lu\N{U+010D}i\N{U+0107}"; # Lučić, from the RFC 4515 examples

例子：

$ perl demo.pl
\75\31
\4c\75\c4\8d\69\c4\87

或者使用矢量标志的替代方法：

use Encode qw/encode/;

sub valueencode ($) {
    sprintf '\%*vx', "\\", encode('UTF-8', $_[0]);
}

---

最后，一个更智能的版本只在必要时转义 ASCII 字符（以及多字节字符，即使在仔细阅读 RFC 后，如果它们是有效的 UTF-8，它们实际上并不需要）：

# Encode according to RFC 4515 valueencoding grammar rules:
#
# Text is UTF-8 encoded. Bytes can be escaped with the sequence
# \XX, where the X's are hex digits.
#
# The characters NUL, LPAREN, RPAREN, ASTERISK and BACKSLASH all MUST
# be escaped.
#
# Bytes > 0x7F that aren't part of a valid UTF-8 sequence MUST be
# escaped. This version assumes there are no such bytes and that input
# is a ASCII or Unicode string.
#
# Single bytes and valid multibyte UTF-8 sequences CAN be escaped,
# with each byte escaped separately. This version escapes multibyte
# sequences, to give ASCII results.
sub valueencode ($) {
    my $encoded = "";
    for my $byte (unpack 'U0C*', $_[0]) {
        if (($byte >= 0x01 && $byte <= 0x27) ||
            ($byte >= 0x2B && $byte <= 0x5B) ||
            ($byte >= 0x5D && $byte <= 0x7F)) {
            $encoded .= chr $byte;
        } else {
            $encoded .= sprintf '\%02x', $byte;
        }
    }
    return $encoded;
}

此版本从上述示例返回字符串'u1'和'Lu\c4\8di\c4\87' 。

Answer 2

简而言之，一种方法就像问题所说的那样：将字符串拆分为字符，获取它们的序数，然后将格式转换为十六进制； 然后把它们粘在一起。 我不知道如何获得\nn格式，所以我会“手工”制作。 例如

my $s = join '', map { sprintf '\%x', ord }  split //, 'u1';

或使用向量标志%v将字符串视为整数的“向量”

my $s = sprintf '\%*vx', '\\', 'u1';

这也可以使用pack + unpack来完成，请参见下面的链接。 如果输入字符范围很广，也请参阅该页面。 ^†

请参阅ord和sprintf以及更多类似的页面。

---

^†如果有非 ASCII 输入，那么您可能需要对其进行编码以获得八位字节，如果它们要转义（而不是整个代码点）

use Encode qw(encode);

my $s = sprintf '\%*vx', '\\', encode('UTF_8', $input);

有关更多信息，请参见链接页面。