生成 macOS 框架时如何保留公共标头的目录布局

Question

我有一个 CMake 项目，用于 C++ 库（当前版本，CMake v3.21），我正在移植到 macOS，我正在研究将库生成为OSX Framework 。

到目前为止，我已经按照 CMake 关于add_library的文档进行操作，并根据CMake 关于其 FRAMEWORK 目标属性的文档将FRAMEWORK属性添加到库目标。 这似乎大部分工作，除了作为其PUBLIC_HEADER属性的一部分导出的 header 文件的目录结构从导出中被剥离和展平。

为了说明这个问题，让我们考虑以下项目树：

include
└── A
    ├── A.hpp
    └── subA
        └── SubA.hpp
src
├── A.cpp
└── SubA.cpp

以下 CMake 项目在 macOS 上编译时生成一个 OSX 框架：

cmake_minimum_required(VERSION 3.21)

project(libA LANGUAGES CXX)


set(a_INCLUDES
    include/A/A.hpp
    include/A/subA/SubA.hpp
)

set(a_SOURCES
    src/A.cpp
    src/SubA.cpp
)

add_library(a
    ${a_INCLUDES}
    ${a_SOURCES}
)

set_target_properties(a
    PROPERTIES
    FRAMEWORK YES
    PUBLIC_HEADER "${a_INCLUDES}"
)

target_include_directories(a
    PUBLIC
    ${CMAKE_SOURCE_DIR}/include
)

但是，生成的框架将其Headers中包含的 header 文件的目录结构展平，如下所示：

build/a.framework
├── Headers -> Versions/Current/Headers
├── Resources -> Versions/Current/Resources
├── Versions
│   ├── A
│   │   ├── Headers
│   │   │   ├── A.hpp
│   │   │   └── SubA.hpp
│   │   ├── Resources
│   │   │   └── Info.plist
│   │   └── a
│   └── Current -> A
└── a -> Versions/Current/a

所以，这是我的问题：CMake 是否支持保留作为 OSX 框架的一部分提供的公共标头的目录树布局？ 如果是这样，我们需要在项目中做什么才能确保保留目录树布局？

Answer 1

虽然您希望将您的公共和私有标头放置在Headers目录下，包括它们的相对路径，但您所经历的情况并非如此。 整个路径组件被剥离。 这同样适用于Resource目录中的分层结构资源。

要实现此目的，您可以使用set_source_files_properties命令在每个 header 上设置MACOSX_PACKAGE_LOCATION属性。 该位置是指向 header 的路径加上Headers前缀，例如Headers/A用于您的A/A.hpp header 和Headers/A/subA用于您的A/subA/SubA.hpp header。

通常，项目为此使用一个小便利工具 function，它从给定的标头中去除不需要的前缀和文件名，并添加安装前缀。

function(set_macosx_properties _file_prefixes _install_prefix _source_files)
  foreach(_file ${_source_files})
    get_filename_component(_loc "${_file}" DIRECTORY)
    foreach(_prefix ${_file_prefixes})
      string(REPLACE "${_prefix}" "" _loc "${_loc}")
    endforeach()
    set_source_files_properties(${_file} PROPERTIES MACOSX_PACKAGE_LOCATION ${_install_prefix}${_loc})
  endforeach()
endfunction()

取决于您的 header 和资源文件是如何提供的，您可以像这样使用它：

set_macosx_properties("include" "Headers" "${a_INCLUDES}")

set_macosx_properties("data" "Resources" "${a_RESOURCES}")