如何获取文件夹中存在的文件列表并动态传递文件名以使用批处理脚本循环获取文件中存在的内容

Question

在一个目录中，我有一个 multiple.txt 文件。 例如：

abc.txt
bcd.txt
def.txt

现在，在这些文件中的每一个中，我都有如下凭证信息：

Hostname: 10.87.99.09
username: qwerty
password: ytrewq

这些是文件夹中存在的每个.txt 文件中的内容。

现在我的要求是，我需要向用户询问文件夹路径，一旦用户提供了文件夹路径，我需要将文件夹中存在的.txt 文件一个一个地取出，然后将文件中存在的服务器凭据分配给一个变量，以便我可以将这些变量传递给 sqlcmd 命令以执行操作。

例如，主机名：10.23.32.21，然后 a= 10.23.32.21 这样我就可以将 %a% 传递给 sqlcmd 命令。

因为，我是批处理脚本的新手，我通过执行 rnd 编写了一些代码：

@echo off
setlocal enableDelayedExpansion
set /p file="Please enter file Name: "
cd %file%
set /x ID=1

for /f "delims=" %%G in ('dir *.txt /b') do (
set filename[!ID!]=%%~G
for /f "tokens=1,2delims=: " %%a in ('findstr /n . %%~G') do set "name[%%a]=%%b"
set c= %name[1]%
echo%c%
set /x ID+=1
)

set filename
endlocal
pause

并获得 output 作为：

Please enter file Name: C:\Users\LENOVO\Desktop\testing\multiple
The syntax of the command is incorrect.
ECHO is off.
The syntax of the command is incorrect.
ECHO is off.
The syntax of the command is incorrect.
ECHO is off.
The syntax of the command is incorrect.
filename[]=test.txt

我也尝试了很多东西但无法得到结果。 有人可以帮我解决这些问题吗？ 提前致谢！

Answer 1

@ECHO OFF
setlocal enableDelayedExpansion
:again
set /p file="Please enter file Name: "
pushd "%file%"
if /i "%cd%" neq "%file%" echo Change directory failed&goto again
set /A ID=0
    
for /f "delims=" %%G in ('dir /b /a-d *.txt') do (
 set /A ID+=1
 set "filename[!ID!]=%%~G"
 for /f "tokens=1,2delims=: " %%a in (%%G) do if /i "%%a"=="hostname" set "name[!ID!]=%%b"
)

popd

set filename
set name

FOR /L %%c IN (1,1,%ID%) DO IF DEFINED name[%%c] ECHO file : !filename[%%c]! name !name[%%c]!

GOTO :EOF

您的set /x应该set /a ，因此出现语法错误。

pushd保存当前目录并切换到指定目录。 popd返回到原始目录。

%cd%由系统设置为当前目录，因此如果pushd失败，那么比较将是N ot EQ ual，将产生消息并重新提示用户。 /i使比较不区分大小写。

如果您从0而不是1开始id ，则id将包含找到的条目的计数。

首先指定dir选项的纯粹约定。 /od添加以排除任何符合文件名掩码*.txt的子目录名称。

在循环中，只需读取名称在%%G中的文件。 令牌化，使令牌 1 ( %%a ) 是文件中目标行上的Hostname ，令牌 2 ( %%b ) 是10.87.99.09 。 使用if to select 适当的行，这样它就不必是第一行，并将name[!ID!]设置为该值。

你的代码的问题是findstr /n...会产生一行1:Hostname: 10.87.99.09所以 Token 1 是1 ，Token 2 Hostname和 token 3 10.87.99.09所以你需要select 标记 1 和 3 而不是 1 和 2，您会假设第 1 行包含hostname 。

然后是set c= %name[1]% 。 Batch 会将此命令的c设置为Space ，因为在遇到for...%%G..时name[1]未定义。 set c=!name[1]! 会做你想做的。 请参阅 Stephan 的 DELAYEDEXPANSION 链接： https://stackoverflow.com/a/30284028/2128947

出于类似的原因， echo%c%会被评估为echo ，这就是为什么你得到echo is off "error" 报告的原因。

使用set "var1=data"设置字符串值 - 这避免了由尾随空格引起的问题。

最后， for /L将列出进程在文件中找到hostname的那些文件名和名称

当您使用点击和咯咯笑的方法执行批处理时，如果发现语法错误或脚本运行完成，批处理 window 将关闭。 您应该改为打开“命令提示符”并从那里运行您的批处理，以便 window 保持打开状态并显示任何（错误）消息。

Answer 2

下面是一个替代示例，它应该只选择三行，以不区分大小写的字符串Hostname: 、 username:和password:开头，顺序不限。 它应该创建一个变量%args% ，具有以下格式的扩展值（基于您提交的示例文件） ：- -S tcp:10.87.99.09 -U qwerty -P ytrewq

@Echo Off
SetLocal EnableExtensions DisableDelayedExpansion

:AskFilePath
Set "file="
Set /P "file=Please provide the absolute or relative file path - %CD%>"
If Not Defined file GoTo AskFilePath
Set file 2>NUL | %SystemRoot%\System32\findstr.exe /RC:"[\?\*]" 1>NUL && (
    GoTo AskFilePath
)
For %%G In (
    "%file%"
) Do If "%%~aG" Lss "-" (
    GoTo AskFilePath
) Else If "%%~aG" GEq "d" GoTo AskFilePath

Set "args="
For /F "Tokens=1,* Delims=: " %%G In (
    'Type "%file%" 2^>NUL'
) Do If Not Defined args (
    If /I "%%G" == "Hostname" Set "args=-S tcp:%%H"
    If /I "%%G" == "username" Set "args=-U %%H"
    If /I "%%G" == "password" Set "args=-P %%H" 
) Else (
    SetLocal EnableDelayedExpansion
    For %%I In ("!args!") Do (
        EndLocal
        If /I "%%G" == "Hostname" Set "args=%%~I -S tcp:%%H"
        If /I "%%G" == "username" Set "args=%%~I -U %%H"
        If /I "%%G" == "password" Set "args=%%~I -P %%H"    
    )
)
If Not Defined args GoTo EndScript

Rem Your code goes here, [two demonstration lines given].
Set args
Pause

:EndScript
EndLocal
GoTo :EOF