如何使用它在 vb.net 中添加内联值或多行字符串

Question

我不知道创建一个多行字符串请最好的解决方案。 下面的代码并不都使用多行字符串。 您可以看到我注释掉的代码是因为我不知道如何创建多行字符串。

谢谢杰克 '信息代码

Public Shared Function GetReceipt(ByVal transaction_Conflict As Transaction) As String
            Return GenerateReceiptTemplate().Replace("<Orders/>", GetOrderRows(transaction_Conflict)).Replace("<Total/>", transaction_Conflict.Total.ToString() & "PHP").Replace("<Cash/>", transaction_Conflict.Cash.ToString() & "PHP").Replace("<Change/>", transaction_Conflict.Change.ToString() & "PHP").Replace("<Id/>", transaction_Conflict.Id).Replace("<Cashier/>", transaction_Conflict.GetCashier().Fullname).Replace("<Date/>", transaction_Conflict.Date.ToString())
        End Function

Private Shared Function GetOrderRows(ByVal transaction_Conflict As Transaction) As String
            Dim result As String = ""
            transaction_Conflict.GetOrders().ForEach(Sub(item As Order)
                result &= "<tr>"
                result &= "<td>" & item.GetProduct().Name & "</td>"
                result &= "<td align='center'>x " & item.Quantity & "</td>"
                result &= "<td align='right'>" & item.Subtotal & "PHP</td>"
                result &= "</tr>"
            End Sub)
            Return result
        End Function

 'code output in VB.NET
        
 Private Shared Function GenerateReceiptTemplate() As String
            Return "<center>" & vbCrLf &
                           "<font size='24px'><b>WcDonalds</b></font><br/>" & vbCrLf &
                           "<span>wcdonalds@gmail.com</span>" & vbCrLf &
                       "</center>" & vbCrLf &
                       "<br/><br/>" & vbCrLf &
                       "<table width='100%'>" & vbCrLf &
                           "<thead>" & vbCrLf &
                               "<tr>" & vbCrLf &
                                   "<th align='left'>Product Name</th>" & vbCrLf &
                                   "<th align='center'>Quantity</th>" & vbCrLf &
                                   "<th align='right'>Subtotal</th>" & vbCrLf &
                               "</tr>" & vbCrLf &
                           "</thead>" & vbCrLf &
                           "<tbody>" & vbCrLf &
                               "<Orders/>" & vbCrLf &
                           "</tbody>" & vbCrLf &
                       "</table>" & vbCrLf &
                       "<br/>" & vbCrLf &
                       "<center>---------------------------------------</center>" & vbCrLf &
                       "<br/>" & vbCrLf &

            'Total: <b><Total/></b><br/>
            'Cash: <b><Cash/></b><br/>
            'Change: <b><Change/></b><br/>
            '               <br/>
            'Transaction ID:   #<Id/><br/>
            'Cashier: <Cashier/><br/>
            'Date: <Date/><br/>

            '               <br/>
            '               <center>---------------------------------------</center>
            '               <br/>

            '               <center><b>Thanks For visiting WcDonalds</b></center>





        End Function

Answer 1

您只需在多行中键入String文字，在第一行使用左双引号，在最后一行使用右双引号。 请注意，您需要将除第一条物理行之外的所有内容都推到代码窗口的左侧，因为您包含的任何前导空格都将被视为String的一部分。 例如

    Dim str = "First Line
Second Line
Third Line"

我不记得这个特性是什么时候引入的，所以它可能在 VB 2010 中不可用。在这种情况下，您仍然可以使用 XML 文字，例如

    Dim str = <text>First Line
Second Line
Third Line</text>.Value

Answer 2

你的 HTML 是一团糟。 这只是好一点。

    Dim xe As XElement = <div>
                             <p style="text-align: center; font-size: 24px;font-weight:700;">WcDonalds</p>
                             <p style="text-align: center;">wcdonalds@gmail.com</p>
                             <table style="width: 100%;">
                                 <thead>
                                     <tr>
                                         <th style="width: 33.3%; text-align: left;">Product Name</th>
                                         <th style="width: 33.3%; text-align: center;">Quantity</th>
                                         <th style="width: 33.3%; text-align: right;">Subtotal</th>
                                     </tr>
                                 </thead>
                                 <tbody>
                                     <tr>
                                         <td style="width: 33.3%; text-align: left;">a product</td>
                                         <td style="width: 33.3%; text-align: center;">1</td>
                                         <td style="width: 33.3%; text-align: right;">$1.23</td>
                                     </tr>
                                 </tbody>
                             </table>
                             <br/>
                             <p style="text-align: center;">---------------------------------------</p>
                             <p>Total</p>
                             <p>Cash</p>
                             <p>Change</p>
                             <p style="text-align: center;">---------------------------------------</p>
                             <p style="text-align: center; font-weight:700;">Thanks For visiting WcDonalds</p>
                         </div>

    Return xe.ToString

Answer 3

文本可以保存为嵌入式资源（文本文件）并从那里检索。 这有助于一个人的代码看起来更干净。

尝试以下操作：

与 2010 年相比：

打开解决方案资源管理器

• 在 VS 菜单中，选择查看
• 选择解决方案资源管理器

打开属性窗口

• 在 VS 菜单中，选择查看
• 选择属性窗口

添加文件夹（名称：模板）

• 在解决方案资源管理器中，右键单击 <项目名称>
• 选择添加
• 选择新文件夹
• 输入所需的名称（例如：模板）

添加文本文件（名称：ReceiptTemplate.txt）

• 在解决方案资源管理器中，右键单击您刚刚创建的新文件夹（例如：模板）
• 选择添加
• 选择新项目
• 展开常见项目
• 单击常规
• 选择文本文件（名称：ReceiptTemplate.txt）
• 点击添加

设置文本文件的属性

• 在解决方案资源管理器中，单击您添加的文本文件（例如：ReceiptTemplate.txt）
• 在属性窗口中，将Build Action设置为Embedded Resource

将所需的文本添加到文本文件。 例如：

收据模板.txt ：

<center>
  <font size='24px'>
    <b>ABC Cafe</b>
  </font>
  <br/>
  <span>abccafe@gmail.com</span>
</center>

<br/>
<br/>

<table width='100%'>
    <thead>
        <tr>
            <th align='left'>Product Name</th>
            <th align='center'>Quantity</th>
            <th align='right'>Subtotal</th>
        </tr>
    </thead>
    <tbody>
        <Orders/>
    </tbody>
</table>
<br/>
<center>---------------------------------------</center>
<br/>

Total: <b><Total/></b><br/>
Cash: <b><Cash/></b><br/>
Change: <b><Change/></b><br/>
<br/>
Transaction ID:   #<Id/><br/>
Cashier: <Cashier/><br/>
Date: <Date/><br/>

<br/>

<center>---------------------------------------</center>
<br/>
<center><b>Thanks For visiting ABC Cafe</b></center>

添加一个模块（名称：HelperLoadResource.vb）

'Notes: 
'        Need to set property Build Action: Embedded Resource For Each file that 
'        needs to be loaded
'
'Resources: 
'        https'stackoverflow.com/questions/3314140/how-to-read-embedded-resource-text-file

Imports System.Text
Imports System.IO
Imports System.Reflection

Module HelperLoadResource

    Public Function ReadResource(filename As String) As String
        Return ReadResource(filename, System.Text.Encoding.UTF8)
    End Function

    Public Function ReadResource(filename As String, fileEncoding As System.Text.Encoding) As String
        Dim fqResourceName As String = String.Empty
        Dim result As String = String.Empty

        'get executing assembly
        Dim execAssembly As System.Reflection.Assembly = System.Reflection.Assembly.GetExecutingAssembly()

        'get resource names
        Dim resourceNames As String() = execAssembly.GetManifestResourceNames()

        If resourceNames IsNot Nothing AndAlso resourceNames.Length > 0 Then
            For Each rName As String In resourceNames
                If rName.EndsWith(filename) Then
                    fqResourceName = rName
                    Exit For
                End If
            Next

            If String.IsNullOrEmpty(fqResourceName) Then
                Throw New Exception(String.Format("Resource '{0}' not found.", filename))
            End If

            'get file text
            Using s As Stream = execAssembly.GetManifestResourceStream(fqResourceName)
                Using reader As StreamReader = New StreamReader(s, fileEncoding)

                    'read text
                    result = reader.ReadToEnd()
                End Using
            End Using
        End If

        Return result
    End Function
End Module

注意：这也适用于较新版本的 Visual Studio，但是“添加文本文件”中列出的一些步骤是不同的。

---

文件/文件夹结构应类似于以下内容：

---

用法：

Dim receiptTemplate As String = HelperLoadResource.ReadResource("ReceiptTemplate.txt")

资源：

• 如何读取嵌入式资源文本文件

Answer 4

好吧，这里你需要的只是生成和返回收据的第一个函数。 我将使用相同的XElement方法修改您上一个问题的答案，以从transaction_Conflict参数中获取值。

对于标签，附加来自用<%= %>括起来的transaction_Conflict对象的相应值。 对于表格部分，调用<%= %>中的transaction_Conflict.GetOrders()方法获取列表并调用.Select扩展方法创建行和单元格，如代码所示。

Public Shared Function GetReceipt(ByVal transaction_Conflict As Transaction) As String
    Return <html>
                <center>
                    <font size='24px'><b>WcDonalds</b></font><br/>
                    <span>wcdonalds@gmail.com</span>
                </center><br/>
                <table width='100%'>
                    <thead>
                        <tr>
                            <th align='left'>Product Name</th>
                            <th align='center'>Quantity</th>
                            <th align='right'>Subtotal</th>
                        </tr>
                    </thead>
                    <tbody>
                        <%= transaction_Conflict.GetOrders().Select(
                            Function(order)
                                Return _
                        <tr>
                            <td><%= order.GetProduct().Name %></td>
                            <td align='center'><%= order.Quantity %></td>
                            <td align='right'><%= order.SubTotal %></td>
                        </tr>
                            End Function) %>
                    </tbody>
                </table>
                <br/><hr/><br/>
            
                Total: <b><%= transaction_Conflict.Total %> PHP</b><br/>
                Cash: <b><%= transaction_Conflict.Cash %> PHP</b><br/>
                Change: <b><%= transaction_Conflict.Change %> PHP</b><br/><br/>
                Transaction ID: #<%= transaction_Conflict.Id %><br/>
                Cashier: <%= transaction_Conflict.GetCashier().Fullname %>><br/>
                Date: <%= transaction_Conflict.Date.ToString() %><br/><br/><hr/>

                <center><b>Thanks For visiting WcDonalds</b></center>
            </html>.ToString()
End Function

在我的浏览器中生成类似：